Data-Password-1.08/ 0000755 0001750 0000144 00000000000 12171043324 012742 5 ustar oded users Data-Password-1.08/MANIFEST 0000644 0001750 0000144 00000000321 10464641611 014075 0 ustar oded users Changes
Makefile.PL
MANIFEST
Password.pm
t/IsBadPasswordForUNIX.t
t/IsBadPassword.t
t/words Dummy dictionary for tests
README
META.yml Module meta-data (added by MakeMaker)
Data-Password-1.08/Changes 0000644 0001750 0000144 00000001633 12171043166 014244 0 ustar oded users Revision history for Perl extension Data::Password.
0.01 Wed Jan 16 17:26:03 2002
- original version; created by h2xs 1.19
1.03 Sat Apr 3 23:50:12 2004
- Added new variable @DICTIONARIES
- Documentation updated
1.04 Sat Aug 7 11:28:11 IDT 2004
- Fixed error message for $MAXLEN==0 (thanks to James Saint-Rossy
who submitted a patch)
1.05 Sat Aug 7 22:47:42 IDT 2004
- Fixed test.pl to work on platforms with no dictionaries.
(Thanks to 'Barbie' from cpan-testers)
1.06 Wed Aug 2 22:14:35 IDT 2006
- Added dummy dictionary.
- Stricter dictionary checking (Requested by Gary Bennett)
If your dictionary has entries with '.' password is
not checked against these entries.
1.07 Fri Aug 4 13:18:42 IDT 2006
- CheckDict optimized for speed.
- Symbol::gensym remmoved.
1.08 Mon Jul 15 21:35:11 IDT 2013
- minor documentation update (by Neil Bowers)
Data-Password-1.08/README 0000644 0001750 0000144 00000005714 12171042000 013617 0 ustar oded users NAME
Data::Password - Perl extension for assessing password quality.
SYNOPSIS
use Data::Password qw(IsBadPassword);
print IsBadPassword("clearant");
# Bad password - contains the word 'clear', only lowercase
use Data::Password qw(:all);
$DICTIONARY = 0;
$GROUPS = 0;
print IsBadPassword("clearant");
DESCRIPTION
This module checks potential passwords for crackability. It checks that
the password is in the appropriate length, that it has enough character
groups, that it does not contain the same characters repeatedly or
ascending or descending characters, or charcters close to each other in
the keyboard. It will also attempt to search the ispell word file for
existance of whole words. The module's policies can be modified by
changing its variables. (Check "VARIABLES"). For doing it, it is
recommended to import the ':all' shortcut when requiring it:
*use Data::Password qw(:all);*
FUNCTIONS
1 IsBadPassword(password)
Returns undef if the password is ok, or a textual description of the
fault if any.
2 IsBadPasswordForUNIX(user, password)
Performs two additional checks: compares the password against the
login name and the "comment" (ie, real name) found on the user file.
VARIABLES
1 $DICTIONARY
Minimal length for dictionary words that are not allowed to appear
in the password. Set to false to disable dictionary check.
2 $FOLLOWING
Maximal length of characters in a row to allow if the same or
following. If $FOLLOWING_KEYBOARD is true (default), the module will
also check for alphabetical keys following, according to the English
keyboard layout. Set $FOLLOWING to false to bypass this check.
3 $GROUPS
Groups of characters are lowercase letters, uppercase letters,
digits and the rest of the allowed characters. Set $GROUPS to the
number of minimal character groups a password is required to have.
Setting to false or to 1 will bypass the check.
4 $MINLEN
$MAXLEN
Minimum and maximum length of a password. Both can be set to false.
5 @DICTIONARIES
Location where we are looking for dictionary files. You may want to
set this variable if you are using not *NIX like operating system.
FILES
* /usr/dict/web2
* /usr/dict/words
* /etc/passwd
SEE ALSO
See Data::Password::BasicCheck if you need only basic password checking.
Other modules Data::Password::Common, Data::Password::Check,
Data::Password::Meter, Data::Password::Entropy and
String::Validator::Password
AUTHOR
Raz Information Systems, razinf@cpan.org
COPYRIGHT
Copyright (c) 2001 - 2013 Raz Information Systems Ltd.
This package is distributed under the same terms as Perl itself, see the
Artistic License on Perl's home page.
Data-Password-1.08/Password.pm 0000644 0001750 0000144 00000014102 12171041717 015104 0 ustar oded users package Data::Password;
# Ariel Brosh (RIP), January 2002, for Raz Information Systems
# Oded S. Resnik, 3 April 2004, for Raz Information Systems
use strict;
require Exporter;
use vars qw($DICTIONARY $FOLLOWING $GROUPS $MINLEN $MAXLEN
$FOLLOWING_KEYBOARD @DICTIONARIES
$VERSION @ISA @EXPORT_OK %EXPORT_TAGS);
@EXPORT_OK = qw($DICTIONARY $FOLLOWING $GROUPS $FOLLOWING_KEYBOARD
@DICTIONARIES $MINLEN $MAXLEN IsBadPassword IsBadPasswordForUNIX);
%EXPORT_TAGS = ('all' => [@EXPORT_OK]);
@ISA = qw(Exporter);
$VERSION = '1.08';
$DICTIONARY = 5;
$FOLLOWING = 3;
$FOLLOWING_KEYBOARD = 1;
$GROUPS = 2;
$MINLEN = 6;
$MAXLEN = 8;
@DICTIONARIES = qw(/usr/dict/web2 /usr/dict/words /usr/share/dict/words /usr/share/dict/linux.words);
sub OpenDictionary {
foreach my $sym (@DICTIONARIES) {
return $sym if -r $sym;
}
return;
}
sub CheckDict {
return unless $DICTIONARY;
my $pass = shift;
my $dict = OpenDictionary();
return unless $dict;
open (DICT,"$dict") || return;
$pass = lc($pass);
while (my $dict_line = ) {
chomp ($dict_line);
next if length($dict_line) < $DICTIONARY;
$dict_line = lc($dict_line);
if (index($pass,$dict_line)>-1) {
close(DICT);
return $dict_line;
}
}
close(DICT);
return;
}
sub CheckSort {
return unless $FOLLOWING;
my $pass = shift;
foreach (1 .. 2) {
my @letters = split(//, $pass);
my $diffs;
my $last = shift @letters;
foreach (@letters) {
$diffs .= chr((ord($_) - ord($last) + 256 + 65) % 256);
$last = $_;
}
my $len = $FOLLOWING - 1;
return 1 if $diffs =~ /([\@AB])\1{$len}/;
return unless $FOLLOWING_KEYBOARD;
my $mask = $pass;
$pass =~ tr/A-Z/a-z/;
$mask ^= $pass;
$pass =~ tr/qwertyuiopasdfghjklzxcvbnm/abcdefghijKLMNOPQRStuvwxyz/;
$pass ^= $mask;
}
return;
}
sub CheckTypes {
return undef unless $GROUPS;
my $pass = shift;
my @groups = qw(a-z A-Z 0-9 ^A-Za-z0-9);
my $count;
foreach (@groups) {
$count++ if $pass =~ /[$_]/;
}
$count < $GROUPS;
}
sub CheckCharset {
my $pass = shift;
$pass =~ /[\0-\x1F \x7F]/;
}
sub CheckLength {
my $pass = shift;
my $len = length($pass);
return 1 if ($MINLEN && $len < $MINLEN);
return 1 if ($MAXLEN && $len > $MAXLEN);
return;
}
sub IsBadPassword {
my $pass = shift;
if (CheckLength($pass)) {
if ($MAXLEN && $MINLEN) {
return "Not between $MINLEN and $MAXLEN characters";
}
elsif (!$MAXLEN) { return "Not $MINLEN characters or greater"; }
else { return "Not less than or equal to $MAXLEN characters"; }
}
return "contains bad characters" if CheckCharset($pass);
return "contains less than $GROUPS character groups"
if CheckTypes($pass);
return "contains over $FOLLOWING leading characters in sequence"
if CheckSort($pass);
my $dict = CheckDict($pass);
return "contains the dictionary word '$dict'" if $dict;
return;
}
sub IsBadPasswordForUNIX {
my ($user, $pass) = @_;
my $reason = IsBadPassword($pass);
return $reason if $reason;
my $tuser = $user;
$tuser =~ s/[^a-zA-Z]//g;
return "is based on the username" if ($pass =~ /$tuser/i);
my ($name,$passwd,$uid,$gid,
$quota,$comment,$gcos,$dir,$shell,$expire) = getpwnam($user);
return unless $comment;
foreach ($comment =~ /([A-Z]+)/ig) {
return "is based on the finger information" if ($pass =~ /$_/i);
}
return;
}
1;
__END__
=head1 NAME
Data::Password - Perl extension for assessing password quality.
=head1 SYNOPSIS
use Data::Password qw(IsBadPassword);
print IsBadPassword("clearant");
# Bad password - contains the word 'clear', only lowercase
use Data::Password qw(:all);
$DICTIONARY = 0;
$GROUPS = 0;
print IsBadPassword("clearant");
=head1 DESCRIPTION
This module checks potential passwords for crackability.
It checks that the password is in the appropriate length,
that it has enough character groups, that it does not contain the same
characters repeatedly or ascending or descending characters, or charcters
close to each other in the keyboard.
It will also attempt to search the ispell word file for existance
of whole words.
The module's policies can be modified by changing its variables. (Check L<"VARIABLES">).
For doing it, it is recommended to import the ':all' shortcut
when requiring it:
I