IRI-0.013/ 000755 000765 000024 00000000000 14676277401 012245 5 ustar 00greg staff 000000 000000 IRI-0.013/inc/ 000755 000765 000024 00000000000 14676277400 013015 5 ustar 00greg staff 000000 000000 IRI-0.013/SIGNATURE 000644 000765 000024 00000005246 14676277401 013540 0 ustar 00greg staff 000000 000000 This file contains message digests of all files listed in MANIFEST,
signed via the Module::Signature module, version 0.88.
To verify the content in this distribution, first make sure you have
Module::Signature installed, then type:
% cpansign -v
It will check each file's integrity, as well as the signature's
validity. If "==> Signature verified OK! <==" is not displayed,
the distribution may already have been compromised, and you should
not run its Makefile.PL or Build.PL.
-----BEGIN PGP SIGNED MESSAGE-----
Hash: RIPEMD160
SHA256 c719fe7260a2234277fb32f0bf48bc20cf3c797c9b194e4a56214db2105e44fa Changes
SHA256 0cb463fb465ba4f5639147e857b956462fc2cfee2df68554f019bc405f431370 MANIFEST
SHA256 ef2aa244a3abcd23cc2d952912304c16655621a6b0c4bd1139952c5624e58ade META.yml
SHA256 59b2ee817b8a2627406847471057df3cfbc0d5268192fbefc8d2afc0e9a50959 Makefile.PL
SHA256 12340142517a8cd8cbc74570cec1e9f0b209b701917a054cb57306e55a6f035d README
SHA256 cd5397bbe618f5bbd4e12a33b0cf5d21114e771c2dbd0ce28e2135beb52c35a8 inc/Module/Install.pm
SHA256 1b5430a46a35142ef8914d8c745196fca825defc9dfa7e389299bf294613825e inc/Module/Install/AuthorTests.pm
SHA256 798836f9ccb8d204b1be31fc3835631f57e9d818b21a8f0d14bfcfb82ff4a72a inc/Module/Install/Base.pm
SHA256 d64cd4c16f83c5baf11f64a44bea3a0abc060a49da5aba040f0eb01394bf75ab inc/Module/Install/Can.pm
SHA256 668306ae2fad17b3049f885251b8679497c4eb8d5c4b0d13f5c95bda331d1f00 inc/Module/Install/DOAPChangeSets.pm
SHA256 65d7a6098bf3f829e8c1c2865476d3537aa6f0ad0ffc9149e10812c856529043 inc/Module/Install/Fetch.pm
SHA256 70c4b77acab3ff51dfb318110369607cb109e1c319459249623b787cf3859750 inc/Module/Install/Makefile.pm
SHA256 14556386168007ce913e669fc08a332ccdb6140246fd55a90c879b5190c1b57a inc/Module/Install/Metadata.pm
SHA256 4c746c02c5cc19bed4c352e76205b4adff4c45ce8310d71294e1b83c059659c2 inc/Module/Install/Win32.pm
SHA256 d3d9b4583243c470ae895defa4c44564485b53693cba1c50ab0320768f443e97 inc/Module/Install/WriteAll.pm
SHA256 70ce2c66074e5cf95a2932b186fc2f876efaec86f6e1e20d326b85453f211c8f lib/IRI.pm
SHA256 bbceafb90362a8518ecb267bdf2cc74d9ff2ca609c0d4574615d6b514f8a9da7 meta/changes.ttl
SHA256 4417564b7d518113f64bed37b71cc2e71878f4439d4f0483a352a340c7307dc0 t/00-simple.t
SHA256 7de4d22c6f2109895c9ce998cd516b26c28d8742bde50f34f59e7bdc8486996f t/base_resolution.t
SHA256 1737883fcdb17ca4f32bc68154fb8c1c56b6983a9d7b2746790de7286cc53b21 t/bugs.t
SHA256 606e752df44d8377c6bbdd4387fa21980ef843253c1c467c44d9ee6a6fe2c9cf t/coercion.t
SHA256 2bed522ac451881ad783c7ead37f0ab4a2b7e17abdd43be61e696c8f5d480fa0 t/rel.t
SHA256 76a58ab06a5b907415ab8835240c4af63272d60435f381eff60700c1885338d6 xt/pod-coverage.t
SHA256 2b04b20ff767801fde2fb6435361dc8ca0a9b60dda6cb0bbd18dd52962e1c1a3 xt/pod.t
IRI-0.013/PaxHeader/Changes 000644 000765 000024 00000000460 14676277375 015523 x ustar 00greg staff 000000 000000 30 mtime=1727627005.415752061
64 LIBARCHIVE.xattr.com.apple.TextEncoding=VVRGLTg7MTM0MjE3OTg0
55 SCHILY.xattr.com.apple.TextEncoding=UTF-8;134217984
85 LIBARCHIVE.xattr.com.apple.FinderInfo=VEVYVAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
70 SCHILY.xattr.com.apple.FinderInfo=TEXT
IRI-0.013/Changes 000644 000765 000024 00000003530 14676277375 013553 0 ustar 00greg staff 000000 000000 IRI
===
Created: 2014-07-23
Home page:
Bug tracker:
Maintainer: Gregory Todd Williams
0.013 2024-09-29
- (Update) New version to address bad data in META.yml in 0.12 release.
0.012 2024-09-28
- (Update) Fix bug that inadvertently allowed trailing newlines at the end
of an IRI.
0.011 2020-02-20
- (Update) Add IRI->rel method.
0.010 2019-12-26
- (Update) Fix component resolution to remove dots when base resolution
occurs without a scheme but with a user/port/host.
0.009 2018-10-30
- (Update) Reduce Minimum Perl Version to 5.10 (#12 from @tehmoth).
0.008 2017-08-06
- (Update) Fix typo in regex rule causing problems parsing codepoints
beyond BMP (#11).
0.007 2017-04-03
- (Addition) Add query_form accessor and set_query_param constructor (#4).
- (Update) Updated Makefile.PL for perl 5.26.
0.006 2016-07-19
- (Update) Fix regular expression use of quantifiers (#8 from Karl
Williamson).
0.005 2016-04-04
- (Addition) Add ability to lazily parse IRI components.
- (Addition) Add cpanfile, with Module::Install deps (#5 from Alberto
Simões).
- (Addition) Added Try::Tiny to list of build requirements (github issue
#3).
- (Update) Improve performance of IRI component parsing.
- (Update) Update POD coverage test to ignore private attributes (#6 from
Alberto Simões).
- (Update) Updated required version of Type::Tiny to 0.008 to support use
of InstanceOf (#7 from Alexandr Ciornii).
0.004 2014-09-25
- (Update) Changed IRI to use old-style VERSION declaration.
- (Update) Moved modules from Moose to Moo.
0.003 2014-08-11
- (Addition) Added coercion from Str to IRI.
0.002 2014-08-09
- (Addition) Added as_string method.
0.001 2014-08-02
- (Addition) First release.
IRI-0.013/MANIFEST 000644 000765 000024 00000001063 14676277400 013375 0 ustar 00greg staff 000000 000000 Changes
inc/Module/Install.pm
inc/Module/Install/AuthorTests.pm
inc/Module/Install/Base.pm
inc/Module/Install/Can.pm
inc/Module/Install/DOAPChangeSets.pm
inc/Module/Install/Fetch.pm
inc/Module/Install/Makefile.pm
inc/Module/Install/Metadata.pm
inc/Module/Install/Win32.pm
inc/Module/Install/WriteAll.pm
lib/IRI.pm
Makefile.PL
MANIFEST This list of files
META.yml
meta/changes.ttl
t/00-simple.t
t/base_resolution.t
t/bugs.t
t/coercion.t
t/rel.t
xt/pod-coverage.t
xt/pod.t
README
SIGNATURE Public-key signature (added by MakeMaker)
IRI-0.013/meta/ 000755 000765 000024 00000000000 14676277400 013172 5 ustar 00greg staff 000000 000000 IRI-0.013/t/ 000755 000765 000024 00000000000 14676277400 012507 5 ustar 00greg staff 000000 000000 IRI-0.013/xt/ 000755 000765 000024 00000000000 14676277400 012677 5 ustar 00greg staff 000000 000000 IRI-0.013/README 000644 000765 000024 00000001426 13601305566 013117 0 ustar 00greg staff 000000 000000 The IRI module is a Perl implementation of Internationalized Resource
Identifiers (IRIs) as defined by [RFC 3987](http://www.ietf.org/rfc/rfc3987.txt).
SYNOPSIS
use IRI;
my $base = IRI->new(value => "http://www.hestebedg\x{e5}rd.dk/");
my $i = IRI->new(value => '#frag', base => $base);
say $i->scheme; # 'http'
say $i->path; # '/'
say $i->as_string; # 'http://www.hestebedgård.dk/#frag'
INSTALLATION
This package requires Moose.
To install, run:
perl Makefile.PL
make
make test
make install
COPYRIGHT
Copyright (C) 2014--2018 Gregory Williams. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
AUTHOR
Gregory Todd Williams
IRI-0.013/META.yml 000644 000765 000024 00000001521 14676277375 013527 0 ustar 00greg staff 000000 000000 ---
abstract: 'Internationalized Resource Identifiers'
author:
- 'Gregory Todd Williams C<< >>'
- 'Gregory Todd Williams '
build_requires:
ExtUtils::MakeMaker: 6.59
Test::More: 0.88
Try::Tiny: 0
URI: 0
configure_requires:
ExtUtils::MakeMaker: 6.59
distribution_type: module
dynamic_config: 1
generated_by: 'Module::Install version 1.21'
license: perl
meta-spec:
url: http://module-build.sourceforge.net/META-spec-v1.4.html
version: 1.4
name: IRI
no_index:
directory:
- inc
- t
- xt
requires:
Moo: 0
MooX::HandlesVia: 0
Type::Tiny: 0.008
perl: 5.10.1
resources:
bugtracker: https://github.com/kasei/perl-iri/issues
homepage: http://search.cpan.org/dist/IRI/
license: http://dev.perl.org/licenses/
repository: http://github.com/kasei/perl-iri/
version: '0.013'
IRI-0.013/lib/ 000755 000765 000024 00000000000 14676277400 013012 5 ustar 00greg staff 000000 000000 IRI-0.013/Makefile.PL 000644 000765 000024 00000001317 13623411534 014205 0 ustar 00greg staff 000000 000000 use strict;
use warnings;
use lib '.';
use inc::Module::Install;
name 'IRI';
all_from 'lib/IRI.pm';
author 'Gregory Todd Williams ';
license 'perl';
build_requires 'Test::More' => 0.88;
build_requires 'Try::Tiny' => 0;
perl_version '5.010001';
requires 'Moo' => 0;
requires 'MooX::HandlesVia' => 0;
requires 'Type::Tiny' => 0.008; #InstanceOf
build_requires 'URI' => 0;
resources(
'homepage' => "http://search.cpan.org/dist/IRI/",
'repository' => "http://github.com/kasei/perl-iri/",
'bugtracker' => "https://github.com/kasei/perl-iri/issues"
);
author_tests('xt');
write_doap_changes "meta/changes.ttl", "Changes", "turtle";
sign;
WriteAll;
IRI-0.013/lib/PaxHeader/IRI.pm 000644 000765 000024 00000000225 14676276625 015753 x ustar 00greg staff 000000 000000 30 mtime=1727626645.551059747
64 LIBARCHIVE.xattr.com.apple.TextEncoding=VVRGLTg7MTM0MjE3OTg0
55 SCHILY.xattr.com.apple.TextEncoding=UTF-8;134217984
IRI-0.013/lib/IRI.pm 000644 000765 000024 00000040722 14676276625 014010 0 ustar 00greg staff 000000 000000 =encoding utf8
=head1 NAME
IRI - Internationalized Resource Identifiers
=head1 VERSION
This document describes IRI version 0.013
=head1 SYNOPSIS
use IRI;
my $i = IRI->new(value => 'https://example.org:80/index#frag');
say $i->scheme; # 'https'
say $i->path; # '/index'
my $base = IRI->new(value => "http://www.hestebedg\x{e5}rd.dk/");
my $i = IRI->new(value => '#frag', base => $base);
say $i->abs; # 'http://www.hestebedgård.dk/#frag'
# Defer parsing of the IRI until necessary
my $i = IRI->new(value => "http://www.hestebedg\x{e5}rd.dk/", lazy => 1);
say $i->path; # path is parsed here
=head1 DESCRIPTION
The IRI module provides an object representation for Internationalized
Resource Identifiers (IRIs) as defined by
L and supports their parsing,
serializing, and base resolution.
=head1 ATTRIBUTES
=over 4
=item C<< lazy >>
A boolean value indicating whether the IRI should be parsed (and validated)
during object construction (false), or parsed only when an IRI component is
accessed (true). If no components are ever needed (e.g. an IRI is constructed
with a C<< value >> and C<< value >> is the only accessor ever called), no
parsing will take place.
=back
=head1 METHODS
=over 4
=item C<< as_string >>
Returns the absolute IRI string resolved against the base IRI, if present;
the relative IRI string otherwise.
=item C<< abs >>
Returns the absolute IRI string (resolved against the base IRI if present).
=item C<< scheme >>
=item C<< host >>
=item C<< port >>
=item C<< user >>
=item C<< path >>
=item C<< fragment >>
=item C<< query >>
Returns the respective component of the parsed IRI.
=cut
{
package IRI;
use v5.10.1;
use warnings;
our $VERSION = '0.013';
use Moo;
use MooX::HandlesVia;
use Types::Standard qw(Str InstanceOf HashRef Bool);
use Scalar::Util qw(blessed);
# class_type 'URI';
# coerce 'IRI' => from 'Str' => via { IRI->new( value => $_ ) };
# coerce 'IRI' => from 'URI' => via { IRI->new( value => $_->as_string ) };
has 'lazy' => (is => 'ro', isa => Bool, default => 0);
has '_initialized' => (is => 'rw', isa => Bool, default => 0, init_arg => undef);
has 'base' => (is => 'ro', isa => InstanceOf['IRI'], predicate => 'has_base', coerce => sub {
my $base = shift;
if (blessed($base)) {
if ($base->isa('IRI')) {
return $base;
} elsif ($base->isa('URI')) {
return IRI->new( value => $base->as_string );
}
} else {
return IRI->new($base);
}
});
has 'value' => (is => 'ro', isa => Str, default => '');
has 'components' => (is => 'ro', writer => '_set_components');
has 'abs' => (is => 'ro', lazy => 1, builder => '_abs');
has 'resolved_components' => (
is => 'ro',
isa => HashRef,
lazy => 1,
builder => '_resolved_components',
predicate => 1,
handles_via => 'Hash',
handles => {
authority => [ accessor => 'authority' ],
scheme => [ accessor => 'scheme' ],
host => [ accessor => 'host' ],
port => [ accessor => 'port' ],
user => [ accessor => 'user' ],
path => [ accessor => 'path' ],
fragment => [ accessor => 'fragment' ],
query => [ accessor => 'query' ],
},
);
around BUILDARGS => sub {
my $orig = shift;
my $class = shift;
if (scalar(@_) == 1) {
return $class->$orig(value => shift);
}
return $class->$orig(@_);
};
sub BUILD {
my $self = shift;
if ($self->has_resolved_components) {
$self->_set_components($self->resolved_components);
$self->_initialized(1);
} else {
unless ($self->lazy) {
my $comp = $self->_parse_components($self->value);
}
}
}
before [qw(components as_string abs resolved_components scheme host port user path fragment query)] => sub {
my $self = shift;
if (not $self->_initialized) {
# warn "Lazily initializing IRI";
my $comp = $self->_parse_components($self->value);
}
};
# These regexes are (mostly) from the syntax grammar in RFC 3987
my $HEXDIG = qr<[0-9A-F]>o;
my $ALPHA = qr<[A-Za-z]>o;
my $subdelims = qr<[!\$&'()*+,;=]>xo;
my $gendelims = qr<[":/?#@] | \[ | \]>xo;
my $reserved = qr<${gendelims} | ${subdelims}>o;
my $unreserved = qr<${ALPHA} | [0-9] | [-._~]>xo;
my $pctencoded = qr<%[0-9A-Fa-f]{2}>o;
my $decoctet = qr<
[0-9] # 0-9
| [1-9][0-9] # 10-99
| 1 [0-9]{2} # 100-199
| 2 [0-4] [0-9] # 200-249
| 25 [0-5] # 250-255
>xo;
my $IPv4address = qr<
# IPv4address
${decoctet}[.]${decoctet}[.]${decoctet}[.]${decoctet}
>xo;
my $h16 = qr<${HEXDIG}{1,4}>o;
my $ls32 = qr<
( ${h16} : ${h16} )
| ${IPv4address}
>xo;
my $IPv6address = qr<
# IPv6address
( ( ${h16} : ){6} ${ls32})
| ( :: ( ${h16} : ){5} ${ls32})
| (( ${h16} )? :: ( ${h16} : ){4} ${ls32})
| (( ( ${h16} : ){0,1} ${h16} )? :: ( ${h16} : ){3} ${ls32})
| (( ( ${h16} : ){0,2} ${h16} )? :: ( ${h16} : ){2} ${ls32})
| (( ( ${h16} : ){0,3} ${h16} )? :: ${h16} : ${ls32})
| (( ( ${h16} : ){0,4} ${h16} )? :: ${ls32})
| (( ( ${h16} : ){0,5} ${h16} )? :: ${h16})
| (( ( ${h16} : ){0,6} ${h16} )? ::)
>xo;
my $IPvFuture = qrxo;
my $IPliteral = qr<\[
# IPliteral
(${IPv6address} | ${IPvFuture})
\]
>xo;
my $port = qr<(?[0-9]*)>o;
my $scheme = qr<(?${ALPHA} ( ${ALPHA} | [0-9] | [+] | [-] | [.] )*)>xo;
my $iprivate = qr<[\x{E000}-\x{F8FF}] | [\x{F0000}-\x{FFFFD}] | [\x{100000}-\x{10FFFD}]>xo;
my $ucschar = qr<
[\x{a0}-\x{d7ff}] | [\x{f900}-\x{fdcf}] | [\x{fdf0}-\x{ffef}]
| [\x{10000}-\x{1FFFD}] | [\x{20000}-\x{2FFFD}] | [\x{30000}-\x{3FFFD}]
| [\x{40000}-\x{4FFFD}] | [\x{50000}-\x{5FFFD}] | [\x{60000}-\x{6FFFD}]
| [\x{70000}-\x{7FFFD}] | [\x{80000}-\x{8FFFD}] | [\x{90000}-\x{9FFFD}]
| [\x{A0000}-\x{AFFFD}] | [\x{B0000}-\x{BFFFD}] | [\x{C0000}-\x{CFFFD}]
| [\x{D0000}-\x{DFFFD}] | [\x{E1000}-\x{EFFFD}]
>xo;
my $iunreserved = qr<${ALPHA}|[0-9]|[-._~]|${ucschar}>o;
my $ipchar = qr<(${iunreserved})|(${pctencoded})|(${subdelims})|:|@>o;
my $ifragment = qr<(?(${ipchar}|/|[?])*)>o;
my $iquery = qr<(?(${ipchar}|${iprivate}|/|[?])*)>o;
my $isegmentnznc = qr<(${iunreserved}|${pctencoded}|${subdelims}|@)+ # non-zero-length segment without any colon ":"
>xo;
my $isegmentnz = qr<${ipchar}+>o;
my $isegment = qr<${ipchar}*>o;
my $ipathempty = qr<>o;
my $ipathrootless = qr<(?${isegmentnz}(/${isegment})*)>o;
my $ipathnoscheme = qr<(?${isegmentnznc}(/${isegment})*)>o;
my $ipathabsolute = qr<(?/(${isegmentnz}(/${isegment})*)?)>o;
my $ipathabempty = qr<(?(/${isegment})*)>o;
my $ipath = qr<
${ipathabempty} # begins with "/" or is empty
| ${ipathabsolute} # begins with "/" but not "//"
| ${ipathnoscheme} # begins with a non-colon segment
| ${ipathrootless} # begins with a segment
| ${ipathempty} # zero characters
>xo;
my $iregname = qr<(${iunreserved}|${pctencoded}|${subdelims})*>o;
my $ihost = qr<(?${IPliteral}|${IPv4address}|${iregname})>o;
my $iuserinfo = qr<(?(${iunreserved}|${pctencoded}|${subdelims}|:)*)>o;
my $iauthority = qr<(?(${iuserinfo}@)?${ihost}(:${port})?)>o;
my $irelativepart = qr<
(//${iauthority}${ipathabempty})
| ${ipathabsolute}
| ${ipathnoscheme}
| ${ipathempty}
>xo;
my $irelativeref = qr<${irelativepart}([?]${iquery})?(#${ifragment})?>o;
my $ihierpart = qr<(//${iauthority}${ipathabempty})|(${ipathabsolute})|(${ipathrootless})|(${ipathempty})>o;
my $absoluteIRI = qr<${scheme}:${ihierpart}([?]${iquery})?>o;
my $IRI = qr<${scheme}:${ihierpart}([?]${iquery})?(#${ifragment})?>o;
my $IRIreference = qr<${IRI}|${irelativeref}>o;
sub _parse_components {
my $self = shift;
my $v = shift;
my $c;
if ($v =~ /\A(${IRIreference})\Z/mso and length($1) == length($v)) {
%$c = %+;
} else {
use Data::Dumper;
die "Not a valid IRI? " . Dumper($v);
}
$c->{path} //= '';
$self->_set_components($c);
$self->_initialized(1);
}
sub _merge {
my $self = shift;
my $base = shift;
my $bc = $base->components;
my $c = $self->components;
my $base_has_authority = ($bc->{user} or $bc->{port} or defined($bc->{host}));
if ($base_has_authority and not($bc->{path})) {
return "/" . $c->{path};
} else {
my $bp = $bc->{path};
my @pathParts = split('/', $bp, -1); # -1 limit means $path='/' splits into ('', '')
pop(@pathParts);
push(@pathParts, $c->{path});
my $path = join('/', @pathParts);
return $path;
}
}
sub _remove_dot_segments {
my $self = shift;
my $input = shift;
my @output;
while (length($input)) {
if ($input =~ m<^[.][.]/>) {
substr($input, 0, 3) = '';
} elsif ($input =~ m<^[.]/>) {
substr($input, 0, 2) = '';
} elsif ($input =~ m<^/[.]/>) {
substr($input, 0, 3) = '/';
} elsif ($input eq '/.') {
$input = '/';
} elsif ($input =~ m<^/[.][.]/>) {
substr($input, 0, 4) = '/';
pop(@output);
} elsif ($input eq '/..') {
$input = '/';
pop(@output);
} elsif ($input eq '.') {
$input = '';
} elsif ($input eq '..') {
$input = '';
} else {
my $leadingSlash = ($input =~ m<^/>);
if ($leadingSlash) {
substr($input, 0, 1) = '';
}
my ($part, @parts) = split('/', $input, -1);
$part //= '';
if (scalar(@parts)) {
unshift(@parts, '');
}
$input = join('/', @parts);
if ($leadingSlash) {
$part = "/$part";
}
push(@output, $part);
}
}
my $newPath = join('', @output);
return $newPath;
}
sub _resolved_components {
my $self = shift;
my $value = $self->value;
if ($self->has_base and not($self->components->{scheme})) {
# Resolve IRI relative to the base IRI
my $base = $self->base;
my $v = $self->value;
my $bv = $base->value;
# warn "resolving IRI <$v> relative to the base IRI <$bv>";
my %components = %{ $self->components };
my %base = %{ $base->components };
my %target;
if ($components{scheme}) {
foreach my $k (qw(scheme user port host path query)) {
if (exists $components{$k}) {
$target{$k} = $components{$k};
}
}
} else {
if ($components{user} or $components{port} or defined($components{host})) {
foreach my $k (qw(scheme user port host query)) {
if (exists $components{$k}) {
$target{$k} = $components{$k};
}
}
my $path = $components{path};
$target{path} = $self->_remove_dot_segments($path);
} else {
if ($components{path} eq '') {
$target{path} = $base{path};
if ($components{query}) {
$target{query} = $components{query};
} else {
if ($base{query}) {
$target{query} = $base{query};
}
}
} else {
if ($components{path} =~ m<^/>) {
my $path = $components{path};
$target{path} = $self->_remove_dot_segments($path);
} else {
my $path = $self->_merge($base);
$target{path} = $self->_remove_dot_segments($path);
}
if (defined($components{query})) {
$target{query} = $components{query};
}
}
if ($base{user} or $base{port} or defined($base{host})) {
foreach my $k (qw(user port host)) {
if (exists $base{$k}) {
$target{$k} = $base{$k};
}
}
}
}
if (defined($base{scheme})) {
$target{scheme} = $base{scheme};
}
}
if (defined($components{fragment})) {
$target{fragment} = $components{fragment};
}
return \%target;
}
return $self->components;
}
sub _abs {
my $self = shift;
my $value = $self->_string_from_components( $self->resolved_components );
return $value;
}
=item C<< rel ( $base ) >>
Returns a new relative IRI object which, when resolved against the C<< $base >>
IRI, is equal to this IRI.
=cut
sub rel {
# based on code in URI
my $self = shift;
my $base = shift;
my $rel = IRI->new(value => $self->abs);
if (($base->scheme // '') ne ($rel->scheme // '')) {
return IRI->new(value => $rel->abs);
}
my $scheme = $rel->scheme;
my $auth = $rel->authority;
my $path = $rel->path;
if (!defined($scheme) and !defined($auth)) {
return $rel;
}
my $bscheme = $base->scheme;
my $bauth = $base->authority;
my $bpath = $base->path;
for ($bscheme, $bauth, $auth) {
$_ = '' unless defined($_);
}
if ($scheme eq $bscheme) {
$rel->scheme(undef);
}
unless ($scheme eq $bscheme and $auth eq $bauth) {
return IRI->new(value => $rel->_abs);
}
for ($path, $bpath) {
$_ = "/$_" unless m{^/};
}
# Make it relative by eliminating:
# the scheme,
$rel->scheme(undef);
# ... and authority
$rel->host(undef);
$rel->port(undef);
$rel->user(undef);
my @rparts = split('/', $path);
my @bparts = split('/', $bpath);
shift(@rparts);
shift(@bparts);
if (scalar(@rparts) and (scalar(@bparts) and $rparts[0] ne $bparts[0])) {
# use an absolute path, because $rel differs from $base at the very beginning
} else {
# This loop is based on code from Nicolai Langfeldt .
# First we calculate common initial path components length ($li).
my $li = 1;
while (1) {
my $i = index($path, '/', $li);
last if $i < 0 ||
$i != index($bpath, '/', $li) ||
substr($path,$li,$i-$li) ne substr($bpath,$li,$i-$li);
$li=$i+1;
}
# then we nuke it from both paths
substr($path, 0,$li) = '';
substr($bpath,0,$li) = '';
if ($path eq $bpath) {
$rel->path('');
if (defined($rel->query) and defined($base->query)) {
if ($rel->query eq $base->query) {
$rel->query(undef);
} else {
#
}
} elsif (defined($rel->query)) {
#
} elsif (defined($base->query)) {
$rel->path($path);
} else {
#
}
} else {
# Add one "../" for each path component left in the base path
$path = ('../' x $bpath =~ tr|/|/|) . $path;
$path = "./" if $path eq '';
$rel->path($path);
}
}
return IRI->new(value => $rel->_abs);
}
sub as_string {
my $self = shift;
if ($self->has_base || $self->has_resolved_components) {
return $self->abs;
} else {
return $self->value;
}
}
sub _string_from_components {
my $self = shift;
my $components = shift;
my $iri = "";
if (my $s = $components->{scheme}) {
$iri .= "${s}:";
}
if ($components->{user} or $components->{port} or defined($components->{host})) {
# has authority
$iri .= "//";
if (my $u = $components->{user}) {
$iri .= sprintf('%s@', $u);
}
if (defined(my $h = $components->{host})) {
$iri .= $h // '';
}
if (my $p = $components->{port}) {
$iri .= ":$p";
}
}
if (defined(my $p = $components->{path})) {
$iri .= $p;
}
if (defined(my $q = $components->{query})) {
$iri .= '?' . $q;
}
if (defined(my $f = $components->{fragment})) {
$iri .= '#' . $f;
}
return $iri;
}
sub _encode {
my $str = shift;
$str =~ s~([%])~'%' . sprintf('%02x', ord($1))~ge; # gen-delims
$str =~ s~([/:?#@]|\[|\])~'%' . sprintf('%02x', ord($1))~ge; # gen-delims
$str =~ s~([$!&'()*+,;=])~'%' . sprintf('%02x', ord($1))~ge; # sub-delims
return $str;
}
sub _unencode {
my $str = shift;
if (defined($str)) {
$str =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
}
return $str;
}
=item C<< query_form >>
Returns a HASH of key-value mappings for the unencoded, parsed query form data.
=cut
sub query_form {
my $self = shift;
my $q = $self->query // return;
my @pairs = split(/&/, $q);
return map { _unencode($_) } map { split(/=/, $_) } @pairs;
}
=item C<< set_query_param ( $key => $value ) >>
sets the respective query form value and returns a new L object.
=cut
sub set_query_param {
my $self = shift;
my $q = $self->query // return;
my %map = map { _unencode($_) } map { split(/=/, $_) } split(/&/, $q);
while (my ($k, $v) = splice(@_, 0, 2)) {
$map{$k} = $v;
}
my %c = %{ $self->components };
my @pairs = map { join('=', (_encode($_), _encode($map{$_}))) } keys %map;
warn Dumper(\@pairs);
$c{query} = join('&', @pairs);
my $v = $self->_string_from_components(\%c);
return $self->new( value => $v );
}
}
1;
__END__
=back
=head1 SEE ALSO
L
=head1 AUTHOR
Gregory Todd Williams C<< >>
=head1 COPYRIGHT
Copyright (c) 2014--2024 Gregory Todd Williams. This
program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.
=cut
IRI-0.013/xt/pod.t 000644 000765 000024 00000000233 11760736733 013644 0 ustar 00greg staff 000000 000000 use strict;
use warnings;
use Test::More;
eval "use Test::Pod 1.14";
plan skip_all => "Test::Pod 1.14 required for testing POD" if $@;
all_pod_files_ok();
IRI-0.013/xt/pod-coverage.t 000644 000765 000024 00000001017 12654311536 015427 0 ustar 00greg staff 000000 000000 use strict;
use warnings;
use Test::More;
eval "use Test::Pod::Coverage 1.04";
plan skip_all => "Test::Pod::Coverage 1.04 required for testing POD coverage" if $@;
use Module::Load::Conditional qw[can_load];
my @modules = all_modules();
foreach my $mod (@modules) {
if (can_load( modules => { $mod => 0 } )) {
pod_coverage_ok($mod, {
also_private => [ qw.base components has_base value., qr{^[A-Z][A-Z0-9_]*$} ]
});
} else {
note("Ignoring $mod for POD coverage tests (failed to load)");
}
}
done_testing();
IRI-0.013/t/base_resolution.t 000755 000765 000024 00000003027 13620435067 016067 0 ustar 00greg staff 000000 000000 #!/usr/bin/perl
use v5.14;
use strict;
use warnings;
no warnings 'redefine';
use Test::More;
use Data::Dumper;
use Encode qw(decode_utf8);
use URI;
use utf8;
binmode(\*STDOUT, ':utf8');
use IRI;
sub confirm_tests {
my $base = URI->new(shift->abs);
my $b = $base->as_string;
my $tests = shift;
while (my ($url, $expect) = each %$tests) {
my $u = URI->new_abs($url, $base)->as_string;
is($u, $expect, "CONFIRM: $url [$b]");
}
}
sub run_tests {
my $base = shift;
my $b = $base->abs;
my $tests = shift;
while (my ($url, $expect) = each %$tests) {
my $i = IRI->new(value => $url, base => $base);
is($i->abs, $expect, "$url [$b]");
}
}
subtest 'base resolution tests from rfc3986 5.4.1' => sub {
my $base = IRI->new(value => "http://a/b/c/d;p?q");
my %REL_TESTS = (
"g:h" => "g:h",
"g" => "http://a/b/c/g",
"./g" => "http://a/b/c/g",
"g/" => "http://a/b/c/g/",
"/g" => "http://a/g",
"//g" => "http://g",
"?y" => "http://a/b/c/d;p?y",
"g?y" => "http://a/b/c/g?y",
"#s" => "http://a/b/c/d;p?q#s",
"g#s" => "http://a/b/c/g#s",
"g?y#s" => "http://a/b/c/g?y#s",
";x" => "http://a/b/c/;x",
"g;x" => "http://a/b/c/g;x",
"g;x?y#s" => "http://a/b/c/g;x?y#s",
"" => "http://a/b/c/d;p?q",
"." => "http://a/b/c/",
"./" => "http://a/b/c/",
".." => "http://a/b/",
"../" => "http://a/b/",
"../g" => "http://a/b/g",
"../.." => "http://a/",
"../../" => "http://a/",
"../../g" => "http://a/g",
);
run_tests($base, \%REL_TESTS);
confirm_tests($base, \%REL_TESTS);
};
done_testing();
IRI-0.013/t/coercion.t 000644 000765 000024 00000000536 12365522672 014476 0 ustar 00greg staff 000000 000000 #!/usr/bin/perl
use strict;
use warnings;
no warnings 'redefine';
use Test::More;
use Data::Dumper;
use Try::Tiny;
use utf8;
use_ok( 'IRI' );
use_ok( 'URI' );
{
my $base = URI->new( 'http://example.org/ns/' );
my $i = IRI->new( value => 'foo/', base => $base );
isa_ok($i, 'IRI');
is($i->abs, 'http://example.org/ns/foo/');
}
done_testing();
IRI-0.013/t/bugs.t 000644 000765 000024 00000003063 14676142207 013632 0 ustar 00greg staff 000000 000000 #!/usr/bin/perl
use strict;
use warnings;
no warnings 'redefine';
use Test::More;
use Data::Dumper;
use Try::Tiny;
use utf8;
use_ok( 'IRI' );
{
my $i;
try {
$i = IRI->new(value => 'http://www.xn--orfolkedansere-rqb.dk/#8835/St%C3%A6vne%202013');
} catch {
diag $_;
};
isa_ok($i, 'IRI');
}
{
my $base = IRI->new( value => 'http://a.example/' );
my $i = IRI->new( value => 's', base => $base );
isa_ok($i, 'IRI');
is($i->abs, 'http://a.example/s');
}
{
my $base = IRI->new( value => 'http://a.example/' );
my $i = IRI->new( value => '#', base => $base );
isa_ok($i, 'IRI');
is($i->abs, 'http://a.example/#');
}
{
my $base = IRI->new( value => 'http://example.org/ns/' );
my $i = IRI->new( value => 'foo/', base => $base );
isa_ok($i, 'IRI');
is($i->abs, 'http://example.org/ns/foo/');
}
{
my $i = IRI->new( value => 'file:///Users/eve/data/bob.rdf' );
isa_ok($i, 'IRI');
is($i->abs, 'file:///Users/eve/data/bob.rdf');
}
{
my $base = IRI->new( value => 'file:///Users/eve/data/bob.rdf' );
my $i = IRI->new( value => '', base => $base );
isa_ok($i, 'IRI');
is($i->abs, 'file:///Users/eve/data/bob.rdf');
}
subtest '#11 - parsing codepoints beyond the basic multilingual plane fails due to typo in the IRI regexen' => sub {
my $value = 'http://hak.dbpedia.org/resource/Hàn_(𨧀)';
my $i = IRI->new( value => $value );
isa_ok($i, 'IRI');
is($i->abs, $value);
};
subtest 'trailing newline' => sub {
my $value = "http://example.org/foo/bar\n";
eval { IRI->new( value => $value ) };
ok( $@, 'IRI parsing expected failure' );
};
done_testing();
IRI-0.013/t/00-simple.t 000644 000765 000024 00000005056 13620435072 014375 0 ustar 00greg staff 000000 000000 #!/usr/bin/perl
use strict;
use warnings;
no warnings 'redefine';
use Test::More;
use Data::Dumper;
use utf8;
use_ok( 'IRI' );
{
my $i = IRI->new();
isa_ok($i, 'IRI');
isa_ok($i->components, 'HASH');
is($i->as_string, '');
}
{
my $i = IRI->new(value => 'foo');
isa_ok($i, 'IRI');
is($i->value, 'foo', 'IRI value');
is($i->path, 'foo', 'relative path');
is($i->as_string, 'foo');
}
{
my $i = IRI->new(value => 'https://greg@example.org:80/index?foo=bar#frag');
isa_ok($i, 'IRI');
is($i->scheme, 'https', 'scheme');
is($i->host, 'example.org', 'host');
is($i->port, '80', 'port');
is($i->user, 'greg', 'user');
is($i->path, '/index', 'path');
is($i->fragment, 'frag', 'fragment');
is($i->query, 'foo=bar', 'query');
is($i->as_string, 'https://greg@example.org:80/index?foo=bar#frag');
}
{
my $i = IRI->new(value => 'tag:example.com,2014:火星');
isa_ok($i, 'IRI');
is($i->scheme, 'tag', 'scheme');
is($i->path, 'example.com,2014:火星', 'unicode path');
}
{
my $b = IRI->new(value => 'http://example.org/foo/bar');
my $i = IRI->new(value => 'baz/quux', base => $b);
isa_ok($i, 'IRI');
is($i->abs, 'http://example.org/foo/baz/quux', 'absolute IRI string');
is($i->as_string, $i->abs);
}
{
my $b = IRI->new(value => 'http://example.org/foo/bar');
my $i = IRI->new(value => '/baz/../quux', base => $b);
isa_ok($i, 'IRI');
is($i->abs, 'http://example.org/quux', 'absolute IRI string (removing dots)');
}
{
my $base = IRI->new(value => "http://www.hestebedg\x{e5}rd.dk/");
my $i = IRI->new(value => '#frag', base => $base);
is($i->abs, 'http://www.hestebedgård.dk/#frag', 'absolute unicode IRI string');
is($i->scheme, 'http', 'absolute unicode IRI scheme');
is($i->host, 'www.hestebedgård.dk', 'absolute unicode IRI host');
is($i->port, undef, 'absolute unicode IRI port');
is($i->user, undef, 'absolute unicode IRI user');
is($i->path, '/', 'absolute unicode IRI path');
is($i->fragment, 'frag', 'absolute unicode IRI fragment');
is($i->query, undef, 'absolute unicode IRI query');
}
{
my $i = IRI->new(value => 'baz/quux');
isa_ok($i, 'IRI');
is($i->as_string, 'baz/quux', 'IRI string on relative IRI');
}
{
my $iri = IRI->new(
'resolved_components' => {
'scheme' => 'http',
'path' => '/',
'host' => 'example.com'
},
);
is($iri->abs, 'http://example.com/', 'IRI construction by components');
}
{
my $iri = IRI->new(
lazy => 1,
'resolved_components' => {
'scheme' => 'http',
'path' => '/',
'host' => 'example.com'
},
);
is($iri->abs, 'http://example.com/', 'lazy IRI construction by components');
}
done_testing();
IRI-0.013/t/rel.t 000755 000765 000024 00000011077 13623411534 013454 0 ustar 00greg staff 000000 000000 #!/usr/bin/perl
use v5.14;
use strict;
use warnings;
no warnings 'redefine';
use Test::More;
use Data::Dumper;
use Encode qw(decode_utf8);
use URI;
use utf8;
binmode(\*STDOUT, ':utf8');
use IRI;
sub confirm_tests {
my $base = URI->new(shift->abs);
my $b = $base->as_string;
my $tests = shift;
my @tests = @$tests;
while (my ($url, $expect) = splice(@tests, 0, 2, ())) {
my $i = URI->new($url);
my $r = $i->rel($base);
my $u = URI->new_abs($expect, $base)->as_string;
is($u, $url, "CONFIRM: $url [$b]");
}
}
sub run_tests {
my $base = shift;
my $b = $base->abs;
my $tests = shift;
my @tests = @$tests;
while (my ($url, $expect) = splice(@tests, 0, 2, ())) {
my $i = IRI->new(value => $url);
my $r = $i->rel($base);
# warn "Turning " . $i->abs . " into a relative IRI using base $b ===> " . $r->abs;
is($r->as_string, $expect, "$url [$b]");
}
}
subtest 'rel: scheme,host' => sub {
my $base = IRI->new(value => "http://www.example.org/");
my @REL_TESTS = (
'http://www.example.com/' => '//www.example.com/',
'https://www.example.org/' => 'https://www.example.org/',
'http://www.example.org/' => '',
'http://www.example.org/foo' => 'foo',
'http://www.example.org/foo/bar' => 'foo/bar',
'http://www.example.org/#hello' => '#hello',
'http://www.example.org/?query' => '?query',
'http://www.example.org/foo?query' => 'foo?query',
);
run_tests($base, \@REL_TESTS);
confirm_tests($base, \@REL_TESTS);
};
subtest 'rel: scheme,host,path' => sub {
my $base = IRI->new(value => "http://www.example.org/foo/bar");
my @REL_TESTS = (
'http://www.example.com/' => '//www.example.com/',
'https://www.example.org/' => 'https://www.example.org/',
'http://www.example.org/' => '../',
'http://www.example.org/foo' => '../foo',
'http://www.example.org/foo/bar' => '',
'http://www.example.org/#hello' => '../#hello',
'http://www.example.org/?query' => '../?query',
);
run_tests($base, \@REL_TESTS);
confirm_tests($base, \@REL_TESTS);
};
subtest 'rel: scheme,host,path 2' => sub {
my $base = IRI->new(value => "http://xmlns.com/foaf/0.1/");
my @REL_TESTS = (
'http://xmlns.com/foaf/0.1/name' => 'name',
);
run_tests($base, \@REL_TESTS);
confirm_tests($base, \@REL_TESTS);
};
subtest 'tests derived from rfc3986 5.4.1' => sub {
my $base = IRI->new(value => "http://a/b/c/d;p?q");
my @REL_TESTS = (
"g:h" => "g:h",
"http://a/b/c/g" => "g",
"http://a/b/c/g/" => "g/",
"http://a/g" => "/g",
"http://g" => "//g",
"http://a/b/c/d;p?y" => "?y",
"http://a/b/c/g?y" => "g?y",
"http://a/b/c/d;p?q#s" => "#s",
"http://a/b/c/g#s" => "g#s",
"http://a/b/c/g?y#s" => "g?y#s",
"http://a/b/c/;x" => ";x",
"http://a/b/c/g;x" => "g;x",
"http://a/b/c/g;x?y#s" => "g;x?y#s",
"http://a/b/c/d;p?q" => "",
"http://a/b/c/" => "./",
"http://a/b/" => "../",
"http://a/b/g" => "../g",
"http://a/" => "../../",
"http://a/g" => "/g",
);
run_tests($base, \@REL_TESTS);
confirm_tests($base, \@REL_TESTS);
};
subtest 'rel: scheme,host,path,query' => sub {
my $base = IRI->new(value => "http://example.org/sparql?query=ASK%7B%7D%0A");
my @REL_TESTS = (
'http://example.org/sparql#defaultGraph' => 'sparql#defaultGraph',
);
run_tests($base, \@REL_TESTS);
confirm_tests($base, \@REL_TESTS);
};
subtest 'http relative IRI construction with different bases' => sub {
my $iri = IRI->new(value => 'http://example.org:80/foo/bar/baz#xyz?q=ff');
my $base0 = IRI->new(value => 'http://example.org/');
my $base1 = IRI->new(value => 'http://example.org:80/foo');
my $base2 = IRI->new(value => 'http://example.org:80/foo/');
my $base3 = IRI->new(value => 'http://example.org:80/foo/ba');
my $base4 = IRI->new(value => 'http://example.org:80/foo/bar/?q=ff');
my $base5 = IRI->new(value => 'https://example.org:80/foo/bar/baz');
my $base6 = IRI->new(value => 'http://example.com:80/foo/bar/baz');
my $base7 = IRI->new(value => 'http://example.org:81/foo/bar/baz');
is($iri->rel($base0)->abs, '//example.org:80/foo/bar/baz#xyz?q=ff', 'different port');
is($iri->rel($base1)->abs, 'foo/bar/baz#xyz?q=ff', '/foo');
is($iri->rel($base2)->abs, 'bar/baz#xyz?q=ff', '/bar');
is($iri->rel($base3)->abs, 'bar/baz#xyz?q=ff', '/foo/ba (shared prefix, but ending mid-path)');
is($iri->rel($base4)->abs, 'baz#xyz?q=ff', 'extra query');
is($iri->rel($base5)->abs, 'http://example.org:80/foo/bar/baz#xyz?q=ff', 'different scheme');
is($iri->rel($base6)->abs, '//example.org:80/foo/bar/baz#xyz?q=ff', 'different host');
is($iri->rel($base7)->abs, '//example.org:80/foo/bar/baz#xyz?q=ff', 'different port');
};
done_testing();
IRI-0.013/meta/PaxHeader/changes.ttl 000644 000765 000024 00000000225 14676277350 017303 x ustar 00greg staff 000000 000000 30 mtime=1727626984.025903468
64 LIBARCHIVE.xattr.com.apple.TextEncoding=VVRGLTg7MTM0MjE3OTg0
55 SCHILY.xattr.com.apple.TextEncoding=UTF-8;134217984
IRI-0.013/meta/changes.ttl 000644 000765 000024 00000014132 14676277350 015334 0 ustar 00greg staff 000000 000000 # -*-n3-*-
@prefix dc: .
@prefix dcterms: .
@prefix foaf: .
@prefix doap: .
@prefix xsd: .
@prefix asc: .
@prefix my: .
<>
dc:title "Changes" ;
dc:description "Changes for IRI" ;
dc:subject my:project ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.013" ;
doap:created "2024-09-29" ;
] ;
asc:changes [
asc:update "New version to address bad data in META.yml in 0.12 release." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.012" ;
doap:created "2024-09-28" ;
] ;
asc:changes [
asc:update "Fix bug that inadvertently allowed trailing newlines at the end of an IRI." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.011" ;
doap:created "2020-02-20" ;
] ;
asc:changes [
asc:update "Add IRI->rel method." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.010" ;
doap:created "2019-12-26" ;
] ;
asc:changes [
asc:update "Fix component resolution to remove dots when base resolution occurs without a scheme but with a user/port/host." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.009" ;
doap:created "2018-10-30" ;
] ;
asc:changes [
asc:update "Reduce Minimum Perl Version to 5.10 (#12 from @tehmoth)." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.008" ;
doap:created "2017-08-06" ;
] ;
asc:changes [
asc:update "Fix typo in regex rule causing problems parsing codepoints beyond BMP (#11)." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.007" ;
doap:created "2017-04-03" ;
] ;
asc:changes [
asc:addition "Add query_form accessor and set_query_param constructor (#4)." ;
asc:update "Updated Makefile.PL for perl 5.26." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.006" ;
doap:created "2016-07-19" ;
] ;
asc:changes [
asc:update "Fix regular expression use of quantifiers (#8 from Karl Williamson)." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.005" ;
doap:created "2016-04-04" ;
] ;
asc:changes [
asc:addition "Add ability to lazily parse IRI components." ;
asc:addition "Add cpanfile, with Module::Install deps (#5 from Alberto Simões)." ;
asc:addition "Added Try::Tiny to list of build requirements (github issue #3)." ;
asc:update "Improve performance of IRI component parsing." ;
asc:update "Updated required version of Type::Tiny to 0.008 to support use of InstanceOf (#7 from Alexandr Ciornii)." ;
asc:update "Update POD coverage test to ignore private attributes (#6 from Alberto Simões)." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.004" ;
doap:created "2014-09-25" ;
] ;
asc:changes [
asc:update "Moved modules from Moose to Moo." ;
asc:update "Changed IRI to use old-style VERSION declaration." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.003" ;
doap:created "2014-08-11" ;
] ;
asc:changes [
asc:addition "Added coercion from Str to IRI." ;
] ;
.
dcterms:isVersionOf my:project ;
dcterms:replaces ;
doap:Version [
doap:revision "0.002" ;
doap:created "2014-08-09" ;
] ;
asc:changes [
asc:addition "Added as_string method." ;
] ;
.
dcterms:isVersionOf my:project ;
doap:Version [
doap:revision "0.001" ;
doap:created "2014-08-02" ;
] ;
asc:changes [
asc:addition "First release." ;
# asc:update "" ;
] ;
.
my:project
a doap:Project ;
doap:name "IRI" ;
doap:shortdesc "A Perl implementation of Internationalized Resource Identifiers (IRIs)"@en ;
doap:programming-language "Perl" ;
doap:homepage ;
doap:download-page ;
doap:bug-database ;
doap:maintainer ;
doap:developer ;
doap:documenter ;
doap:tester ;
doap:created "2014-07-23"^^xsd:date ;
doap:license ;
.
a foaf:Person ;
foaf:name "Gregory Todd Williams" ;
foaf:homepage ;
foaf:page ;
foaf:mbox ;
;
.
IRI-0.013/inc/Module/ 000755 000765 000024 00000000000 14676277400 014242 5 ustar 00greg staff 000000 000000 IRI-0.013/inc/Module/Install/ 000755 000765 000024 00000000000 14676277400 015650 5 ustar 00greg staff 000000 000000 IRI-0.013/inc/Module/Install.pm 000644 000765 000024 00000027145 14676277374 016231 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install;
# For any maintainers:
# The load order for Module::Install is a bit magic.
# It goes something like this...
#
# IF ( host has Module::Install installed, creating author mode ) {
# 1. Makefile.PL calls "use inc::Module::Install"
# 2. $INC{inc/Module/Install.pm} set to installed version of inc::Module::Install
# 3. The installed version of inc::Module::Install loads
# 4. inc::Module::Install calls "require Module::Install"
# 5. The ./inc/ version of Module::Install loads
# } ELSE {
# 1. Makefile.PL calls "use inc::Module::Install"
# 2. $INC{inc/Module/Install.pm} set to ./inc/ version of Module::Install
# 3. The ./inc/ version of Module::Install loads
# }
use 5.006;
use strict 'vars';
use Cwd ();
use File::Find ();
use File::Path ();
use vars qw{$VERSION $MAIN};
BEGIN {
# All Module::Install core packages now require synchronised versions.
# This will be used to ensure we don't accidentally load old or
# different versions of modules.
# This is not enforced yet, but will be some time in the next few
# releases once we can make sure it won't clash with custom
# Module::Install extensions.
$VERSION = '1.21';
# Storage for the pseudo-singleton
$MAIN = undef;
*inc::Module::Install::VERSION = *VERSION;
@inc::Module::Install::ISA = __PACKAGE__;
}
sub import {
my $class = shift;
my $self = $class->new(@_);
my $who = $self->_caller;
#-------------------------------------------------------------
# all of the following checks should be included in import(),
# to allow "eval 'require Module::Install; 1' to test
# installation of Module::Install. (RT #51267)
#-------------------------------------------------------------
# Whether or not inc::Module::Install is actually loaded, the
# $INC{inc/Module/Install.pm} is what will still get set as long as
# the caller loaded module this in the documented manner.
# If not set, the caller may NOT have loaded the bundled version, and thus
# they may not have a MI version that works with the Makefile.PL. This would
# result in false errors or unexpected behaviour. And we don't want that.
my $file = join( '/', 'inc', split /::/, __PACKAGE__ ) . '.pm';
unless ( $INC{$file} ) { die <<"END_DIE" }
Please invoke ${\__PACKAGE__} with:
use inc::${\__PACKAGE__};
not:
use ${\__PACKAGE__};
END_DIE
# This reportedly fixes a rare Win32 UTC file time issue, but
# as this is a non-cross-platform XS module not in the core,
# we shouldn't really depend on it. See RT #24194 for detail.
# (Also, this module only supports Perl 5.6 and above).
eval "use Win32::UTCFileTime" if $^O eq 'MSWin32' && $] >= 5.006;
# If the script that is loading Module::Install is from the future,
# then make will detect this and cause it to re-run over and over
# again. This is bad. Rather than taking action to touch it (which
# is unreliable on some platforms and requires write permissions)
# for now we should catch this and refuse to run.
if ( -f $0 ) {
my $s = (stat($0))[9];
# If the modification time is only slightly in the future,
# sleep briefly to remove the problem.
my $a = $s - time;
if ( $a > 0 and $a < 5 ) { sleep 5 }
# Too far in the future, throw an error.
my $t = time;
if ( $s > $t ) { die <<"END_DIE" }
Your installer $0 has a modification time in the future ($s > $t).
This is known to create infinite loops in make.
Please correct this, then run $0 again.
END_DIE
}
# Build.PL was formerly supported, but no longer is due to excessive
# difficulty in implementing every single feature twice.
if ( $0 =~ /Build.PL$/i ) { die <<"END_DIE" }
Module::Install no longer supports Build.PL.
It was impossible to maintain duel backends, and has been deprecated.
Please remove all Build.PL files and only use the Makefile.PL installer.
END_DIE
#-------------------------------------------------------------
# To save some more typing in Module::Install installers, every...
# use inc::Module::Install
# ...also acts as an implicit use strict.
$^H |= strict::bits(qw(refs subs vars));
#-------------------------------------------------------------
unless ( -f $self->{file} ) {
foreach my $key (keys %INC) {
delete $INC{$key} if $key =~ /Module\/Install/;
}
local $^W;
require "$self->{path}/$self->{dispatch}.pm";
File::Path::mkpath("$self->{prefix}/$self->{author}");
$self->{admin} = "$self->{name}::$self->{dispatch}"->new( _top => $self );
$self->{admin}->init;
@_ = ($class, _self => $self);
goto &{"$self->{name}::import"};
}
local $^W;
*{"${who}::AUTOLOAD"} = $self->autoload;
$self->preload;
# Unregister loader and worker packages so subdirs can use them again
delete $INC{'inc/Module/Install.pm'};
delete $INC{'Module/Install.pm'};
# Save to the singleton
$MAIN = $self;
return 1;
}
sub autoload {
my $self = shift;
my $who = $self->_caller;
my $cwd = Cwd::getcwd();
my $sym = "${who}::AUTOLOAD";
$sym->{$cwd} = sub {
my $pwd = Cwd::getcwd();
if ( my $code = $sym->{$pwd} ) {
# Delegate back to parent dirs
goto &$code unless $cwd eq $pwd;
}
unless ($$sym =~ s/([^:]+)$//) {
# XXX: it looks like we can't retrieve the missing function
# via $$sym (usually $main::AUTOLOAD) in this case.
# I'm still wondering if we should slurp Makefile.PL to
# get some context or not ...
my ($package, $file, $line) = caller;
die <<"EOT";
Unknown function is found at $file line $line.
Execution of $file aborted due to runtime errors.
If you're a contributor to a project, you may need to install
some Module::Install extensions from CPAN (or other repository).
If you're a user of a module, please contact the author.
EOT
}
my $method = $1;
if ( uc($method) eq $method ) {
# Do nothing
return;
} elsif ( $method =~ /^_/ and $self->can($method) ) {
# Dispatch to the root M:I class
return $self->$method(@_);
}
# Dispatch to the appropriate plugin
unshift @_, ( $self, $1 );
goto &{$self->can('call')};
};
}
sub preload {
my $self = shift;
unless ( $self->{extensions} ) {
$self->load_extensions(
"$self->{prefix}/$self->{path}", $self
);
}
my @exts = @{$self->{extensions}};
unless ( @exts ) {
@exts = $self->{admin}->load_all_extensions;
}
my %seen;
foreach my $obj ( @exts ) {
while (my ($method, $glob) = each %{ref($obj) . '::'}) {
next unless $obj->can($method);
next if $method =~ /^_/;
next if $method eq uc($method);
$seen{$method}++;
}
}
my $who = $self->_caller;
foreach my $name ( sort keys %seen ) {
local $^W;
*{"${who}::$name"} = sub {
${"${who}::AUTOLOAD"} = "${who}::$name";
goto &{"${who}::AUTOLOAD"};
};
}
}
sub new {
my ($class, %args) = @_;
delete $INC{'FindBin.pm'};
{
# to suppress the redefine warning
local $SIG{__WARN__} = sub {};
require FindBin;
}
# ignore the prefix on extension modules built from top level.
my $base_path = Cwd::abs_path($FindBin::Bin);
unless ( Cwd::abs_path(Cwd::getcwd()) eq $base_path ) {
delete $args{prefix};
}
return $args{_self} if $args{_self};
$base_path = VMS::Filespec::unixify($base_path) if $^O eq 'VMS';
$args{dispatch} ||= 'Admin';
$args{prefix} ||= 'inc';
$args{author} ||= ($^O eq 'VMS' ? '_author' : '.author');
$args{bundle} ||= 'inc/BUNDLES';
$args{base} ||= $base_path;
$class =~ s/^\Q$args{prefix}\E:://;
$args{name} ||= $class;
$args{version} ||= $class->VERSION;
unless ( $args{path} ) {
$args{path} = $args{name};
$args{path} =~ s!::!/!g;
}
$args{file} ||= "$args{base}/$args{prefix}/$args{path}.pm";
$args{wrote} = 0;
bless( \%args, $class );
}
sub call {
my ($self, $method) = @_;
my $obj = $self->load($method) or return;
splice(@_, 0, 2, $obj);
goto &{$obj->can($method)};
}
sub load {
my ($self, $method) = @_;
$self->load_extensions(
"$self->{prefix}/$self->{path}", $self
) unless $self->{extensions};
foreach my $obj (@{$self->{extensions}}) {
return $obj if $obj->can($method);
}
my $admin = $self->{admin} or die <<"END_DIE";
The '$method' method does not exist in the '$self->{prefix}' path!
Please remove the '$self->{prefix}' directory and run $0 again to load it.
END_DIE
my $obj = $admin->load($method, 1);
push @{$self->{extensions}}, $obj;
$obj;
}
sub load_extensions {
my ($self, $path, $top) = @_;
my $should_reload = 0;
unless ( grep { ! ref $_ and lc $_ eq lc $self->{prefix} } @INC ) {
unshift @INC, $self->{prefix};
$should_reload = 1;
}
foreach my $rv ( $self->find_extensions($path) ) {
my ($file, $pkg) = @{$rv};
next if $self->{pathnames}{$pkg};
local $@;
my $new = eval { local $^W; require $file; $pkg->can('new') };
unless ( $new ) {
warn $@ if $@;
next;
}
$self->{pathnames}{$pkg} =
$should_reload ? delete $INC{$file} : $INC{$file};
push @{$self->{extensions}}, &{$new}($pkg, _top => $top );
}
$self->{extensions} ||= [];
}
sub find_extensions {
my ($self, $path) = @_;
my @found;
File::Find::find( {no_chdir => 1, wanted => sub {
my $file = $File::Find::name;
return unless $file =~ m!^\Q$path\E/(.+)\.pm\Z!is;
my $subpath = $1;
return if lc($subpath) eq lc($self->{dispatch});
$file = "$self->{path}/$subpath.pm";
my $pkg = "$self->{name}::$subpath";
$pkg =~ s!/!::!g;
# If we have a mixed-case package name, assume case has been preserved
# correctly. Otherwise, root through the file to locate the case-preserved
# version of the package name.
if ( $subpath eq lc($subpath) || $subpath eq uc($subpath) ) {
my $content = Module::Install::_read($File::Find::name);
my $in_pod = 0;
foreach ( split /\n/, $content ) {
$in_pod = 1 if /^=\w/;
$in_pod = 0 if /^=cut/;
next if ($in_pod || /^=cut/); # skip pod text
next if /^\s*#/; # and comments
if ( m/^\s*package\s+($pkg)\s*;/i ) {
$pkg = $1;
last;
}
}
}
push @found, [ $file, $pkg ];
}}, $path ) if -d $path;
@found;
}
#####################################################################
# Common Utility Functions
sub _caller {
my $depth = 0;
my $call = caller($depth);
while ( $call eq __PACKAGE__ ) {
$depth++;
$call = caller($depth);
}
return $call;
}
sub _read {
local *FH;
open( FH, '<', $_[0] ) or die "open($_[0]): $!";
binmode FH;
my $string = do { local $/; };
close FH or die "close($_[0]): $!";
return $string;
}
sub _readperl {
my $string = Module::Install::_read($_[0]);
$string =~ s/(?:\015{1,2}\012|\015|\012)/\n/sg;
$string =~ s/(\n)\n*__(?:DATA|END)__\b.*\z/$1/s;
$string =~ s/\n\n=\w+.+?\n\n=cut\b.+?\n+/\n\n/sg;
return $string;
}
sub _readpod {
my $string = Module::Install::_read($_[0]);
$string =~ s/(?:\015{1,2}\012|\015|\012)/\n/sg;
return $string if $_[0] =~ /\.pod\z/;
$string =~ s/(^|\n=cut\b.+?\n+)[^=\s].+?\n(\n=\w+|\z)/$1$2/sg;
$string =~ s/\n*=pod\b[^\n]*\n+/\n\n/sg;
$string =~ s/\n*=cut\b[^\n]*\n+/\n\n/sg;
$string =~ s/^\n+//s;
return $string;
}
sub _write {
local *FH;
open( FH, '>', $_[0] ) or die "open($_[0]): $!";
binmode FH;
foreach ( 1 .. $#_ ) {
print FH $_[$_] or die "print($_[0]): $!";
}
close FH or die "close($_[0]): $!";
}
# _version is for processing module versions (eg, 1.03_05) not
# Perl versions (eg, 5.8.1).
sub _version {
my $s = shift || 0;
my $d =()= $s =~ /(\.)/g;
if ( $d >= 2 ) {
# Normalise multipart versions
$s =~ s/(\.)(\d{1,3})/sprintf("$1%03d",$2)/eg;
}
$s =~ s/^(\d+)\.?//;
my $l = $1 || 0;
my @v = map {
$_ . '0' x (3 - length $_)
} $s =~ /(\d{1,3})\D?/g;
$l = $l . '.' . join '', @v if @v;
return $l + 0;
}
sub _cmp {
_version($_[1]) <=> _version($_[2]);
}
# Cloned from Params::Util::_CLASS
sub _CLASS {
(
defined $_[0]
and
! ref $_[0]
and
$_[0] =~ m/^[^\W\d]\w*(?:::\w+)*\z/s
) ? $_[0] : undef;
}
1;
# Copyright 2008 - 2012 Adam Kennedy.
IRI-0.013/inc/Module/Install/Fetch.pm 000644 000765 000024 00000004627 14676277375 017263 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Fetch;
use strict;
use Module::Install::Base ();
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = 'Module::Install::Base';
$ISCORE = 1;
}
sub get_file {
my ($self, %args) = @_;
my ($scheme, $host, $path, $file) =
$args{url} =~ m|^(\w+)://([^/]+)(.+)/(.+)| or return;
if ( $scheme eq 'http' and ! eval { require LWP::Simple; 1 } ) {
$args{url} = $args{ftp_url}
or (warn("LWP support unavailable!\n"), return);
($scheme, $host, $path, $file) =
$args{url} =~ m|^(\w+)://([^/]+)(.+)/(.+)| or return;
}
$|++;
print "Fetching '$file' from $host... ";
unless (eval { require Socket; Socket::inet_aton($host) }) {
warn "'$host' resolve failed!\n";
return;
}
return unless $scheme eq 'ftp' or $scheme eq 'http';
require Cwd;
my $dir = Cwd::getcwd();
chdir $args{local_dir} or return if exists $args{local_dir};
if (eval { require LWP::Simple; 1 }) {
LWP::Simple::mirror($args{url}, $file);
}
elsif (eval { require Net::FTP; 1 }) { eval {
# use Net::FTP to get past firewall
my $ftp = Net::FTP->new($host, Passive => 1, Timeout => 600);
$ftp->login("anonymous", 'anonymous@example.com');
$ftp->cwd($path);
$ftp->binary;
$ftp->get($file) or (warn("$!\n"), return);
$ftp->quit;
} }
elsif (my $ftp = $self->can_run('ftp')) { eval {
# no Net::FTP, fallback to ftp.exe
require FileHandle;
my $fh = FileHandle->new;
local $SIG{CHLD} = 'IGNORE';
unless ($fh->open("|$ftp -n")) {
warn "Couldn't open ftp: $!\n";
chdir $dir; return;
}
my @dialog = split(/\n/, <<"END_FTP");
open $host
user anonymous anonymous\@example.com
cd $path
binary
get $file $file
quit
END_FTP
foreach (@dialog) { $fh->print("$_\n") }
$fh->close;
} }
else {
warn "No working 'ftp' program available!\n";
chdir $dir; return;
}
unless (-f $file) {
warn "Fetching failed: $@\n";
chdir $dir; return;
}
return if exists $args{size} and -s $file != $args{size};
system($args{run}) if exists $args{run};
unlink($file) if $args{remove};
print(((!exists $args{check_for} or -e $args{check_for})
? "done!" : "failed! ($!)"), "\n");
chdir $dir; return !$?;
}
1;
IRI-0.013/inc/Module/Install/Metadata.pm 000644 000765 000024 00000043437 14676277375 017754 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Metadata;
use strict 'vars';
use Module::Install::Base ();
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = 'Module::Install::Base';
$ISCORE = 1;
}
my @boolean_keys = qw{
sign
};
my @scalar_keys = qw{
name
module_name
abstract
version
distribution_type
tests
installdirs
};
my @tuple_keys = qw{
configure_requires
build_requires
requires
recommends
bundles
resources
};
my @resource_keys = qw{
homepage
bugtracker
repository
};
my @array_keys = qw{
keywords
author
};
*authors = \&author;
sub Meta { shift }
sub Meta_BooleanKeys { @boolean_keys }
sub Meta_ScalarKeys { @scalar_keys }
sub Meta_TupleKeys { @tuple_keys }
sub Meta_ResourceKeys { @resource_keys }
sub Meta_ArrayKeys { @array_keys }
foreach my $key ( @boolean_keys ) {
*$key = sub {
my $self = shift;
if ( defined wantarray and not @_ ) {
return $self->{values}->{$key};
}
$self->{values}->{$key} = ( @_ ? $_[0] : 1 );
return $self;
};
}
foreach my $key ( @scalar_keys ) {
*$key = sub {
my $self = shift;
return $self->{values}->{$key} if defined wantarray and !@_;
$self->{values}->{$key} = shift;
return $self;
};
}
foreach my $key ( @array_keys ) {
*$key = sub {
my $self = shift;
return $self->{values}->{$key} if defined wantarray and !@_;
$self->{values}->{$key} ||= [];
push @{$self->{values}->{$key}}, @_;
return $self;
};
}
foreach my $key ( @resource_keys ) {
*$key = sub {
my $self = shift;
unless ( @_ ) {
return () unless $self->{values}->{resources};
return map { $_->[1] }
grep { $_->[0] eq $key }
@{ $self->{values}->{resources} };
}
return $self->{values}->{resources}->{$key} unless @_;
my $uri = shift or die(
"Did not provide a value to $key()"
);
$self->resources( $key => $uri );
return 1;
};
}
foreach my $key ( grep { $_ ne "resources" } @tuple_keys) {
*$key = sub {
my $self = shift;
return $self->{values}->{$key} unless @_;
my @added;
while ( @_ ) {
my $module = shift or last;
my $version = shift || 0;
push @added, [ $module, $version ];
}
push @{ $self->{values}->{$key} }, @added;
return map {@$_} @added;
};
}
# Resource handling
my %lc_resource = map { $_ => 1 } qw{
homepage
license
bugtracker
repository
};
sub resources {
my $self = shift;
while ( @_ ) {
my $name = shift or last;
my $value = shift or next;
if ( $name eq lc $name and ! $lc_resource{$name} ) {
die("Unsupported reserved lowercase resource '$name'");
}
$self->{values}->{resources} ||= [];
push @{ $self->{values}->{resources} }, [ $name, $value ];
}
$self->{values}->{resources};
}
# Aliases for build_requires that will have alternative
# meanings in some future version of META.yml.
sub test_requires { shift->build_requires(@_) }
sub install_requires { shift->build_requires(@_) }
# Aliases for installdirs options
sub install_as_core { $_[0]->installdirs('perl') }
sub install_as_cpan { $_[0]->installdirs('site') }
sub install_as_site { $_[0]->installdirs('site') }
sub install_as_vendor { $_[0]->installdirs('vendor') }
sub dynamic_config {
my $self = shift;
my $value = @_ ? shift : 1;
if ( $self->{values}->{dynamic_config} ) {
# Once dynamic we never change to static, for safety
return 0;
}
$self->{values}->{dynamic_config} = $value ? 1 : 0;
return 1;
}
# Convenience command
sub static_config {
shift->dynamic_config(0);
}
sub perl_version {
my $self = shift;
return $self->{values}->{perl_version} unless @_;
my $version = shift or die(
"Did not provide a value to perl_version()"
);
# Normalize the version
$version = $self->_perl_version($version);
# We don't support the really old versions
unless ( $version >= 5.005 ) {
die "Module::Install only supports 5.005 or newer (use ExtUtils::MakeMaker)\n";
}
$self->{values}->{perl_version} = $version;
}
sub all_from {
my ( $self, $file ) = @_;
unless ( defined($file) ) {
my $name = $self->name or die(
"all_from called with no args without setting name() first"
);
$file = join('/', 'lib', split(/-/, $name)) . '.pm';
$file =~ s{.*/}{} unless -e $file;
unless ( -e $file ) {
die("all_from cannot find $file from $name");
}
}
unless ( -f $file ) {
die("The path '$file' does not exist, or is not a file");
}
$self->{values}{all_from} = $file;
# Some methods pull from POD instead of code.
# If there is a matching .pod, use that instead
my $pod = $file;
$pod =~ s/\.pm$/.pod/i;
$pod = $file unless -e $pod;
# Pull the different values
$self->name_from($file) unless $self->name;
$self->version_from($file) unless $self->version;
$self->perl_version_from($file) unless $self->perl_version;
$self->author_from($pod) unless @{$self->author || []};
$self->license_from($pod) unless $self->license;
$self->abstract_from($pod) unless $self->abstract;
return 1;
}
sub provides {
my $self = shift;
my $provides = ( $self->{values}->{provides} ||= {} );
%$provides = (%$provides, @_) if @_;
return $provides;
}
sub auto_provides {
my $self = shift;
return $self unless $self->is_admin;
unless (-e 'MANIFEST') {
warn "Cannot deduce auto_provides without a MANIFEST, skipping\n";
return $self;
}
# Avoid spurious warnings as we are not checking manifest here.
local $SIG{__WARN__} = sub {1};
require ExtUtils::Manifest;
local *ExtUtils::Manifest::manicheck = sub { return };
require Module::Build;
my $build = Module::Build->new(
dist_name => $self->name,
dist_version => $self->version,
license => $self->license,
);
$self->provides( %{ $build->find_dist_packages || {} } );
}
sub feature {
my $self = shift;
my $name = shift;
my $features = ( $self->{values}->{features} ||= [] );
my $mods;
if ( @_ == 1 and ref( $_[0] ) ) {
# The user used ->feature like ->features by passing in the second
# argument as a reference. Accomodate for that.
$mods = $_[0];
} else {
$mods = \@_;
}
my $count = 0;
push @$features, (
$name => [
map {
ref($_) ? ( ref($_) eq 'HASH' ) ? %$_ : @$_ : $_
} @$mods
]
);
return @$features;
}
sub features {
my $self = shift;
while ( my ( $name, $mods ) = splice( @_, 0, 2 ) ) {
$self->feature( $name, @$mods );
}
return $self->{values}->{features}
? @{ $self->{values}->{features} }
: ();
}
sub no_index {
my $self = shift;
my $type = shift;
push @{ $self->{values}->{no_index}->{$type} }, @_ if $type;
return $self->{values}->{no_index};
}
sub read {
my $self = shift;
$self->include_deps( 'YAML::Tiny', 0 );
require YAML::Tiny;
my $data = YAML::Tiny::LoadFile('META.yml');
# Call methods explicitly in case user has already set some values.
while ( my ( $key, $value ) = each %$data ) {
next unless $self->can($key);
if ( ref $value eq 'HASH' ) {
while ( my ( $module, $version ) = each %$value ) {
$self->can($key)->($self, $module => $version );
}
} else {
$self->can($key)->($self, $value);
}
}
return $self;
}
sub write {
my $self = shift;
return $self unless $self->is_admin;
$self->admin->write_meta;
return $self;
}
sub version_from {
require ExtUtils::MM_Unix;
my ( $self, $file ) = @_;
$self->version( ExtUtils::MM_Unix->parse_version($file) );
# for version integrity check
$self->makemaker_args( VERSION_FROM => $file );
}
sub abstract_from {
require ExtUtils::MM_Unix;
my ( $self, $file ) = @_;
$self->abstract(
bless(
{ DISTNAME => $self->name },
'ExtUtils::MM_Unix'
)->parse_abstract($file)
);
}
# Add both distribution and module name
sub name_from {
my ($self, $file) = @_;
if (
Module::Install::_read($file) =~ m/
^ \s*
package \s*
([\w:]+)
[\s|;]*
/ixms
) {
my ($name, $module_name) = ($1, $1);
$name =~ s{::}{-}g;
$self->name($name);
unless ( $self->module_name ) {
$self->module_name($module_name);
}
} else {
die("Cannot determine name from $file\n");
}
}
sub _extract_perl_version {
if (
$_[0] =~ m/
^\s*
(?:use|require) \s*
v?
([\d_\.]+)
\s* ;
/ixms
) {
my $perl_version = $1;
$perl_version =~ s{_}{}g;
return $perl_version;
} else {
return;
}
}
sub perl_version_from {
my $self = shift;
my $perl_version=_extract_perl_version(Module::Install::_read($_[0]));
if ($perl_version) {
$self->perl_version($perl_version);
} else {
warn "Cannot determine perl version info from $_[0]\n";
return;
}
}
sub author_from {
my $self = shift;
my $content = Module::Install::_read($_[0]);
if ($content =~ m/
=head \d \s+ (?:authors?)\b \s*
([^\n]*)
|
=head \d \s+ (?:licen[cs]e|licensing|copyright|legal)\b \s*
.*? copyright .*? \d\d\d[\d.]+ \s* (?:\bby\b)? \s*
([^\n]*)
/ixms) {
my $author = $1 || $2;
# XXX: ugly but should work anyway...
if (eval "require Pod::Escapes; 1") {
# Pod::Escapes has a mapping table.
# It's in core of perl >= 5.9.3, and should be installed
# as one of the Pod::Simple's prereqs, which is a prereq
# of Pod::Text 3.x (see also below).
$author =~ s{ E<( (\d+) | ([A-Za-z]+) )> }
{
defined $2
? chr($2)
: defined $Pod::Escapes::Name2character_number{$1}
? chr($Pod::Escapes::Name2character_number{$1})
: do {
warn "Unknown escape: E<$1>";
"E<$1>";
};
}gex;
}
elsif (eval "require Pod::Text; 1" && $Pod::Text::VERSION < 3) {
# Pod::Text < 3.0 has yet another mapping table,
# though the table name of 2.x and 1.x are different.
# (1.x is in core of Perl < 5.6, 2.x is in core of
# Perl < 5.9.3)
my $mapping = ($Pod::Text::VERSION < 2)
? \%Pod::Text::HTML_Escapes
: \%Pod::Text::ESCAPES;
$author =~ s{ E<( (\d+) | ([A-Za-z]+) )> }
{
defined $2
? chr($2)
: defined $mapping->{$1}
? $mapping->{$1}
: do {
warn "Unknown escape: E<$1>";
"E<$1>";
};
}gex;
}
else {
$author =~ s{E}{<}g;
$author =~ s{E}{>}g;
}
$self->author($author);
} else {
warn "Cannot determine author info from $_[0]\n";
}
}
#Stolen from M::B
my %license_urls = (
perl => 'http://dev.perl.org/licenses/',
apache => 'http://apache.org/licenses/LICENSE-2.0',
artistic => 'http://opensource.org/licenses/artistic-license.php',
lgpl => 'http://opensource.org/licenses/lgpl-license.php',
bsd => 'http://opensource.org/licenses/bsd-license.php',
gpl => 'http://opensource.org/licenses/gpl-license.php',
gpl2 => 'http://opensource.org/licenses/gpl-2.0.php',
gpl3 => 'http://opensource.org/licenses/gpl-3.0.html',
mit => 'http://opensource.org/licenses/mit-license.php',
mozilla => 'http://opensource.org/licenses/mozilla1.1.php',
open_source => undef,
unrestricted => undef,
restrictive => undef,
unknown => undef,
# these are not actually allowed in meta-spec v1.4 but are left here for compatibility:
apache_1_1 => 'http://apache.org/licenses/LICENSE-1.1',
artistic_2 => 'http://opensource.org/licenses/artistic-license-2.0.php',
lgpl2 => 'http://opensource.org/licenses/lgpl-2.1.php',
lgpl3 => 'http://opensource.org/licenses/lgpl-3.0.html',
);
sub license {
my $self = shift;
return $self->{values}->{license} unless @_;
my $license = shift or die(
'Did not provide a value to license()'
);
$license = __extract_license($license) || lc $license;
$self->{values}->{license} = $license;
# Automatically fill in license URLs
if ( $license_urls{$license} ) {
$self->resources( license => $license_urls{$license} );
}
return 1;
}
sub _extract_license {
my $pod = shift;
my $matched;
return __extract_license(
($matched) = $pod =~ m/
(=head \d \s+ L(?i:ICEN[CS]E|ICENSING)\b.*?)
(=head \d.*|=cut.*|)\z
/xms
) || __extract_license(
($matched) = $pod =~ m/
(=head \d \s+ (?:C(?i:OPYRIGHTS?)|L(?i:EGAL))\b.*?)
(=head \d.*|=cut.*|)\z
/xms
);
}
sub __extract_license {
my $license_text = shift or return;
my @phrases = (
'(?:under )?the same (?:terms|license) as (?:perl|the perl (?:\d )?programming language)' => 'perl', 1,
'(?:under )?the terms of (?:perl|the perl programming language) itself' => 'perl', 1,
'Artistic and GPL' => 'perl', 1,
'GNU general public license' => 'gpl', 1,
'GNU public license' => 'gpl', 1,
'GNU lesser general public license' => 'lgpl', 1,
'GNU lesser public license' => 'lgpl', 1,
'GNU library general public license' => 'lgpl', 1,
'GNU library public license' => 'lgpl', 1,
'GNU Free Documentation license' => 'unrestricted', 1,
'GNU Affero General Public License' => 'open_source', 1,
'(?:Free)?BSD license' => 'bsd', 1,
'Artistic license 2\.0' => 'artistic_2', 1,
'Artistic license' => 'artistic', 1,
'Apache (?:Software )?license' => 'apache', 1,
'GPL' => 'gpl', 1,
'LGPL' => 'lgpl', 1,
'BSD' => 'bsd', 1,
'Artistic' => 'artistic', 1,
'MIT' => 'mit', 1,
'Mozilla Public License' => 'mozilla', 1,
'Q Public License' => 'open_source', 1,
'OpenSSL License' => 'unrestricted', 1,
'SSLeay License' => 'unrestricted', 1,
'zlib License' => 'open_source', 1,
'proprietary' => 'proprietary', 0,
);
while ( my ($pattern, $license, $osi) = splice(@phrases, 0, 3) ) {
$pattern =~ s#\s+#\\s+#gs;
if ( $license_text =~ /\b$pattern\b/i ) {
return $license;
}
}
return '';
}
sub license_from {
my $self = shift;
if (my $license=_extract_license(Module::Install::_read($_[0]))) {
$self->license($license);
} else {
warn "Cannot determine license info from $_[0]\n";
return 'unknown';
}
}
sub _extract_bugtracker {
my @links = $_[0] =~ m#L<(
https?\Q://rt.cpan.org/\E[^>]+|
https?\Q://github.com/\E[\w_]+/[\w_]+/issues|
https?\Q://code.google.com/p/\E[\w_\-]+/issues/list
)>#gx;
my %links;
@links{@links}=();
@links=keys %links;
return @links;
}
sub bugtracker_from {
my $self = shift;
my $content = Module::Install::_read($_[0]);
my @links = _extract_bugtracker($content);
unless ( @links ) {
warn "Cannot determine bugtracker info from $_[0]\n";
return 0;
}
if ( @links > 1 ) {
warn "Found more than one bugtracker link in $_[0]\n";
return 0;
}
# Set the bugtracker
bugtracker( $links[0] );
return 1;
}
sub requires_from {
my $self = shift;
my $content = Module::Install::_readperl($_[0]);
my @requires = $content =~ m/^use\s+([^\W\d]\w*(?:::\w+)*)\s+(v?[\d\.]+)/mg;
while ( @requires ) {
my $module = shift @requires;
my $version = shift @requires;
$self->requires( $module => $version );
}
}
sub test_requires_from {
my $self = shift;
my $content = Module::Install::_readperl($_[0]);
my @requires = $content =~ m/^use\s+([^\W\d]\w*(?:::\w+)*)\s+([\d\.]+)/mg;
while ( @requires ) {
my $module = shift @requires;
my $version = shift @requires;
$self->test_requires( $module => $version );
}
}
# Convert triple-part versions (eg, 5.6.1 or 5.8.9) to
# numbers (eg, 5.006001 or 5.008009).
# Also, convert double-part versions (eg, 5.8)
sub _perl_version {
my $v = $_[-1];
$v =~ s/^([1-9])\.([1-9]\d?\d?)$/sprintf("%d.%03d",$1,$2)/e;
$v =~ s/^([1-9])\.([1-9]\d?\d?)\.(0|[1-9]\d?\d?)$/sprintf("%d.%03d%03d",$1,$2,$3 || 0)/e;
$v =~ s/(\.\d\d\d)000$/$1/;
$v =~ s/_.+$//;
if ( ref($v) ) {
# Numify
$v = $v + 0;
}
return $v;
}
sub add_metadata {
my $self = shift;
my %hash = @_;
for my $key (keys %hash) {
warn "add_metadata: $key is not prefixed with 'x_'.\n" .
"Use appopriate function to add non-private metadata.\n" unless $key =~ /^x_/;
$self->{values}->{$key} = $hash{$key};
}
}
######################################################################
# MYMETA Support
sub WriteMyMeta {
die "WriteMyMeta has been deprecated";
}
sub write_mymeta_yaml {
my $self = shift;
# We need YAML::Tiny to write the MYMETA.yml file
unless ( eval { require YAML::Tiny; 1; } ) {
return 1;
}
# Generate the data
my $meta = $self->_write_mymeta_data or return 1;
# Save as the MYMETA.yml file
print "Writing MYMETA.yml\n";
YAML::Tiny::DumpFile('MYMETA.yml', $meta);
}
sub write_mymeta_json {
my $self = shift;
# We need JSON to write the MYMETA.json file
unless ( eval { require JSON; 1; } ) {
return 1;
}
# Generate the data
my $meta = $self->_write_mymeta_data or return 1;
# Save as the MYMETA.yml file
print "Writing MYMETA.json\n";
Module::Install::_write(
'MYMETA.json',
JSON->new->pretty(1)->canonical->encode($meta),
);
}
sub _write_mymeta_data {
my $self = shift;
# If there's no existing META.yml there is nothing we can do
return undef unless -f 'META.yml';
# We need Parse::CPAN::Meta to load the file
unless ( eval { require Parse::CPAN::Meta; 1; } ) {
return undef;
}
# Merge the perl version into the dependencies
my $val = $self->Meta->{values};
my $perl = delete $val->{perl_version};
if ( $perl ) {
$val->{requires} ||= [];
my $requires = $val->{requires};
# Canonize to three-dot version after Perl 5.6
if ( $perl >= 5.006 ) {
$perl =~ s{^(\d+)\.(\d\d\d)(\d*)}{join('.', $1, int($2||0), int($3||0))}e
}
unshift @$requires, [ perl => $perl ];
}
# Load the advisory META.yml file
my @yaml = Parse::CPAN::Meta::LoadFile('META.yml');
my $meta = $yaml[0];
# Overwrite the non-configure dependency hashes
delete $meta->{requires};
delete $meta->{build_requires};
delete $meta->{recommends};
if ( exists $val->{requires} ) {
$meta->{requires} = { map { @$_ } @{ $val->{requires} } };
}
if ( exists $val->{build_requires} ) {
$meta->{build_requires} = { map { @$_ } @{ $val->{build_requires} } };
}
return $meta;
}
1;
IRI-0.013/inc/Module/Install/AuthorTests.pm 000644 000765 000024 00000002215 14676277375 020506 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::AuthorTests;
use 5.005;
use strict;
use Module::Install::Base;
use Carp ();
#line 16
use vars qw{$VERSION $ISCORE @ISA};
BEGIN {
$VERSION = '0.002';
$ISCORE = 1;
@ISA = qw{Module::Install::Base};
}
#line 42
sub author_tests {
my ($self, @dirs) = @_;
_add_author_tests($self, \@dirs, 0);
}
#line 56
sub recursive_author_tests {
my ($self, @dirs) = @_;
_add_author_tests($self, \@dirs, 1);
}
sub _wanted {
my $href = shift;
sub { /\.t$/ and -f $_ and $href->{$File::Find::dir} = 1 }
}
sub _add_author_tests {
my ($self, $dirs, $recurse) = @_;
return unless $Module::Install::AUTHOR;
my @tests = $self->tests ? (split / /, $self->tests) : 't/*.t';
# XXX: pick a default, later -- rjbs, 2008-02-24
my @dirs = @$dirs ? @$dirs : Carp::confess "no dirs given to author_tests";
@dirs = grep { -d } @dirs;
if ($recurse) {
require File::Find;
my %test_dir;
File::Find::find(_wanted(\%test_dir), @dirs);
$self->tests( join ' ', @tests, map { "$_/*.t" } sort keys %test_dir );
} else {
$self->tests( join ' ', @tests, map { "$_/*.t" } sort @dirs );
}
}
#line 107
1;
IRI-0.013/inc/Module/Install/Win32.pm 000644 000765 000024 00000003403 14676277375 017123 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Win32;
use strict;
use Module::Install::Base ();
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = 'Module::Install::Base';
$ISCORE = 1;
}
# determine if the user needs nmake, and download it if needed
sub check_nmake {
my $self = shift;
$self->load('can_run');
$self->load('get_file');
require Config;
return unless (
$^O eq 'MSWin32' and
$Config::Config{make} and
$Config::Config{make} =~ /^nmake\b/i and
! $self->can_run('nmake')
);
print "The required 'nmake' executable not found, fetching it...\n";
require File::Basename;
my $rv = $self->get_file(
url => 'http://download.microsoft.com/download/vc15/Patch/1.52/W95/EN-US/Nmake15.exe',
ftp_url => 'ftp://ftp.microsoft.com/Softlib/MSLFILES/Nmake15.exe',
local_dir => File::Basename::dirname($^X),
size => 51928,
run => 'Nmake15.exe /o > nul',
check_for => 'Nmake.exe',
remove => 1,
);
die <<'END_MESSAGE' unless $rv;
-------------------------------------------------------------------------------
Since you are using Microsoft Windows, you will need the 'nmake' utility
before installation. It's available at:
http://download.microsoft.com/download/vc15/Patch/1.52/W95/EN-US/Nmake15.exe
or
ftp://ftp.microsoft.com/Softlib/MSLFILES/Nmake15.exe
Please download the file manually, save it to a directory in %PATH% (e.g.
C:\WINDOWS\COMMAND\), then launch the MS-DOS command line shell, "cd" to
that directory, and run "Nmake15.exe" from there; that will create the
'nmake.exe' file needed by this module.
You may then resume the installation process described in README.
-------------------------------------------------------------------------------
END_MESSAGE
}
1;
IRI-0.013/inc/Module/Install/DOAPChangeSets.pm 000644 000765 000024 00000000616 14676277375 020714 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::DOAPChangeSets;
use 5.008;
use parent qw(Module::Install::Base);
use strict;
our $VERSION = '0.206';
our $AUTHOR_ONLY = 1;
sub write_doap_changes {
my $self = shift;
$self->admin->write_doap_changes(@_) if $self->is_admin;
}
sub write_doap_changes_xml {
my $self = shift;
$self->admin->write_doap_changes_xml(@_) if $self->is_admin;
}
1;
__END__
#line 84
IRI-0.013/inc/Module/Install/WriteAll.pm 000644 000765 000024 00000002376 14676277375 017754 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::WriteAll;
use strict;
use Module::Install::Base ();
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = qw{Module::Install::Base};
$ISCORE = 1;
}
sub WriteAll {
my $self = shift;
my %args = (
meta => 1,
sign => 0,
inline => 0,
check_nmake => 1,
@_,
);
$self->sign(1) if $args{sign};
$self->admin->WriteAll(%args) if $self->is_admin;
$self->check_nmake if $args{check_nmake};
unless ( $self->makemaker_args->{PL_FILES} ) {
# XXX: This still may be a bit over-defensive...
unless ($self->makemaker(6.25)) {
$self->makemaker_args( PL_FILES => {} ) if -f 'Build.PL';
}
}
# Until ExtUtils::MakeMaker support MYMETA.yml, make sure
# we clean it up properly ourself.
$self->realclean_files('MYMETA.yml');
if ( $args{inline} ) {
$self->Inline->write;
} else {
$self->Makefile->write;
}
# The Makefile write process adds a couple of dependencies,
# so write the META.yml files after the Makefile.
if ( $args{meta} ) {
$self->Meta->write;
}
# Experimental support for MYMETA
if ( $ENV{X_MYMETA} ) {
if ( $ENV{X_MYMETA} eq 'JSON' ) {
$self->Meta->write_mymeta_json;
} else {
$self->Meta->write_mymeta_yaml;
}
}
return 1;
}
1;
IRI-0.013/inc/Module/Install/Can.pm 000644 000765 000024 00000006405 14676277375 016727 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Can;
use strict;
use Config ();
use ExtUtils::MakeMaker ();
use Module::Install::Base ();
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = 'Module::Install::Base';
$ISCORE = 1;
}
# check if we can load some module
### Upgrade this to not have to load the module if possible
sub can_use {
my ($self, $mod, $ver) = @_;
$mod =~ s{::|\\}{/}g;
$mod .= '.pm' unless $mod =~ /\.pm$/i;
my $pkg = $mod;
$pkg =~ s{/}{::}g;
$pkg =~ s{\.pm$}{}i;
local $@;
eval { require $mod; $pkg->VERSION($ver || 0); 1 };
}
# Check if we can run some command
sub can_run {
my ($self, $cmd) = @_;
my $_cmd = $cmd;
return $_cmd if (-x $_cmd or $_cmd = MM->maybe_command($_cmd));
for my $dir ((split /$Config::Config{path_sep}/, $ENV{PATH}), '.') {
next if $dir eq '';
require File::Spec;
my $abs = File::Spec->catfile($dir, $cmd);
return $abs if (-x $abs or $abs = MM->maybe_command($abs));
}
return;
}
# Can our C compiler environment build XS files
sub can_xs {
my $self = shift;
# Ensure we have the CBuilder module
$self->configure_requires( 'ExtUtils::CBuilder' => 0.27 );
# Do we have the configure_requires checker?
local $@;
eval "require ExtUtils::CBuilder;";
if ( $@ ) {
# They don't obey configure_requires, so it is
# someone old and delicate. Try to avoid hurting
# them by falling back to an older simpler test.
return $self->can_cc();
}
# Do we have a working C compiler
my $builder = ExtUtils::CBuilder->new(
quiet => 1,
);
unless ( $builder->have_compiler ) {
# No working C compiler
return 0;
}
# Write a C file representative of what XS becomes
require File::Temp;
my ( $FH, $tmpfile ) = File::Temp::tempfile(
"compilexs-XXXXX",
SUFFIX => '.c',
);
binmode $FH;
print $FH <<'END_C';
#include "EXTERN.h"
#include "perl.h"
#include "XSUB.h"
int main(int argc, char **argv) {
return 0;
}
int boot_sanexs() {
return 1;
}
END_C
close $FH;
# Can the C compiler access the same headers XS does
my @libs = ();
my $object = undef;
eval {
local $^W = 0;
$object = $builder->compile(
source => $tmpfile,
);
@libs = $builder->link(
objects => $object,
module_name => 'sanexs',
);
};
my $result = $@ ? 0 : 1;
# Clean up all the build files
foreach ( $tmpfile, $object, @libs ) {
next unless defined $_;
1 while unlink;
}
return $result;
}
# Can we locate a (the) C compiler
sub can_cc {
my $self = shift;
if ($^O eq 'VMS') {
require ExtUtils::CBuilder;
my $builder = ExtUtils::CBuilder->new(
quiet => 1,
);
return $builder->have_compiler;
}
my @chunks = split(/ /, $Config::Config{cc}) or return;
# $Config{cc} may contain args; try to find out the program part
while (@chunks) {
return $self->can_run("@chunks") || (pop(@chunks), next);
}
return;
}
# Fix Cygwin bug on maybe_command();
if ( $^O eq 'cygwin' ) {
require ExtUtils::MM_Cygwin;
require ExtUtils::MM_Win32;
if ( ! defined(&ExtUtils::MM_Cygwin::maybe_command) ) {
*ExtUtils::MM_Cygwin::maybe_command = sub {
my ($self, $file) = @_;
if ($file =~ m{^/cygdrive/}i and ExtUtils::MM_Win32->can('maybe_command')) {
ExtUtils::MM_Win32->maybe_command($file);
} else {
ExtUtils::MM_Unix->maybe_command($file);
}
}
}
}
1;
__END__
#line 245
IRI-0.013/inc/Module/Install/Makefile.pm 000644 000765 000024 00000027437 14676277375 017753 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Makefile;
use strict 'vars';
use ExtUtils::MakeMaker ();
use Module::Install::Base ();
use Fcntl qw/:flock :seek/;
use vars qw{$VERSION @ISA $ISCORE};
BEGIN {
$VERSION = '1.21';
@ISA = 'Module::Install::Base';
$ISCORE = 1;
}
sub Makefile { $_[0] }
my %seen = ();
sub prompt {
shift;
# Infinite loop protection
my @c = caller();
if ( ++$seen{"$c[1]|$c[2]|$_[0]"} > 3 ) {
die "Caught an potential prompt infinite loop ($c[1]|$c[2]|$_[0])";
}
# In automated testing or non-interactive session, always use defaults
if ( ($ENV{AUTOMATED_TESTING} or -! -t STDIN) and ! $ENV{PERL_MM_USE_DEFAULT} ) {
local $ENV{PERL_MM_USE_DEFAULT} = 1;
goto &ExtUtils::MakeMaker::prompt;
} else {
goto &ExtUtils::MakeMaker::prompt;
}
}
# Store a cleaned up version of the MakeMaker version,
# since we need to behave differently in a variety of
# ways based on the MM version.
my $makemaker = eval $ExtUtils::MakeMaker::VERSION;
# If we are passed a param, do a "newer than" comparison.
# Otherwise, just return the MakeMaker version.
sub makemaker {
( @_ < 2 or $makemaker >= eval($_[1]) ) ? $makemaker : 0
}
# Ripped from ExtUtils::MakeMaker 6.56, and slightly modified
# as we only need to know here whether the attribute is an array
# or a hash or something else (which may or may not be appendable).
my %makemaker_argtype = (
C => 'ARRAY',
CONFIG => 'ARRAY',
# CONFIGURE => 'CODE', # ignore
DIR => 'ARRAY',
DL_FUNCS => 'HASH',
DL_VARS => 'ARRAY',
EXCLUDE_EXT => 'ARRAY',
EXE_FILES => 'ARRAY',
FUNCLIST => 'ARRAY',
H => 'ARRAY',
IMPORTS => 'HASH',
INCLUDE_EXT => 'ARRAY',
LIBS => 'ARRAY', # ignore ''
MAN1PODS => 'HASH',
MAN3PODS => 'HASH',
META_ADD => 'HASH',
META_MERGE => 'HASH',
PL_FILES => 'HASH',
PM => 'HASH',
PMLIBDIRS => 'ARRAY',
PMLIBPARENTDIRS => 'ARRAY',
PREREQ_PM => 'HASH',
CONFIGURE_REQUIRES => 'HASH',
SKIP => 'ARRAY',
TYPEMAPS => 'ARRAY',
XS => 'HASH',
# VERSION => ['version',''], # ignore
# _KEEP_AFTER_FLUSH => '',
clean => 'HASH',
depend => 'HASH',
dist => 'HASH',
dynamic_lib=> 'HASH',
linkext => 'HASH',
macro => 'HASH',
postamble => 'HASH',
realclean => 'HASH',
test => 'HASH',
tool_autosplit => 'HASH',
# special cases where you can use makemaker_append
CCFLAGS => 'APPENDABLE',
DEFINE => 'APPENDABLE',
INC => 'APPENDABLE',
LDDLFLAGS => 'APPENDABLE',
LDFROM => 'APPENDABLE',
);
sub makemaker_args {
my ($self, %new_args) = @_;
my $args = ( $self->{makemaker_args} ||= {} );
foreach my $key (keys %new_args) {
if ($makemaker_argtype{$key}) {
if ($makemaker_argtype{$key} eq 'ARRAY') {
$args->{$key} = [] unless defined $args->{$key};
unless (ref $args->{$key} eq 'ARRAY') {
$args->{$key} = [$args->{$key}]
}
push @{$args->{$key}},
ref $new_args{$key} eq 'ARRAY'
? @{$new_args{$key}}
: $new_args{$key};
}
elsif ($makemaker_argtype{$key} eq 'HASH') {
$args->{$key} = {} unless defined $args->{$key};
foreach my $skey (keys %{ $new_args{$key} }) {
$args->{$key}{$skey} = $new_args{$key}{$skey};
}
}
elsif ($makemaker_argtype{$key} eq 'APPENDABLE') {
$self->makemaker_append($key => $new_args{$key});
}
}
else {
if (defined $args->{$key}) {
warn qq{MakeMaker attribute "$key" is overriden; use "makemaker_append" to append values\n};
}
$args->{$key} = $new_args{$key};
}
}
return $args;
}
# For mm args that take multiple space-separated args,
# append an argument to the current list.
sub makemaker_append {
my $self = shift;
my $name = shift;
my $args = $self->makemaker_args;
$args->{$name} = defined $args->{$name}
? join( ' ', $args->{$name}, @_ )
: join( ' ', @_ );
}
sub build_subdirs {
my $self = shift;
my $subdirs = $self->makemaker_args->{DIR} ||= [];
for my $subdir (@_) {
push @$subdirs, $subdir;
}
}
sub clean_files {
my $self = shift;
my $clean = $self->makemaker_args->{clean} ||= {};
%$clean = (
%$clean,
FILES => join ' ', grep { length $_ } ($clean->{FILES} || (), @_),
);
}
sub realclean_files {
my $self = shift;
my $realclean = $self->makemaker_args->{realclean} ||= {};
%$realclean = (
%$realclean,
FILES => join ' ', grep { length $_ } ($realclean->{FILES} || (), @_),
);
}
sub libs {
my $self = shift;
my $libs = ref $_[0] ? shift : [ shift ];
$self->makemaker_args( LIBS => $libs );
}
sub inc {
my $self = shift;
$self->makemaker_args( INC => shift );
}
sub _wanted_t {
}
sub tests_recursive {
my $self = shift;
my $dir = shift || 't';
unless ( -d $dir ) {
die "tests_recursive dir '$dir' does not exist";
}
my %tests = map { $_ => 1 } split / /, ($self->tests || '');
require File::Find;
File::Find::find(
sub { /\.t$/ and -f $_ and $tests{"$File::Find::dir/*.t"} = 1 },
$dir
);
$self->tests( join ' ', sort keys %tests );
}
sub write {
my $self = shift;
die "&Makefile->write() takes no arguments\n" if @_;
# Check the current Perl version
my $perl_version = $self->perl_version;
if ( $perl_version ) {
eval "use $perl_version; 1"
or die "ERROR: perl: Version $] is installed, "
. "but we need version >= $perl_version";
}
# Make sure we have a new enough MakeMaker
require ExtUtils::MakeMaker;
if ( $perl_version and $self->_cmp($perl_version, '5.006') >= 0 ) {
# This previous attempted to inherit the version of
# ExtUtils::MakeMaker in use by the module author, but this
# was found to be untenable as some authors build releases
# using future dev versions of EU:MM that nobody else has.
# Instead, #toolchain suggests we use 6.59 which is the most
# stable version on CPAN at time of writing and is, to quote
# ribasushi, "not terminally fucked, > and tested enough".
# TODO: We will now need to maintain this over time to push
# the version up as new versions are released.
$self->build_requires( 'ExtUtils::MakeMaker' => 6.59 );
$self->configure_requires( 'ExtUtils::MakeMaker' => 6.59 );
} else {
# Allow legacy-compatibility with 5.005 by depending on the
# most recent EU:MM that supported 5.005.
$self->build_requires( 'ExtUtils::MakeMaker' => 6.36 );
$self->configure_requires( 'ExtUtils::MakeMaker' => 6.36 );
}
# Generate the MakeMaker params
my $args = $self->makemaker_args;
$args->{DISTNAME} = $self->name;
$args->{NAME} = $self->module_name || $self->name;
$args->{NAME} =~ s/-/::/g;
$args->{VERSION} = $self->version or die <<'EOT';
ERROR: Can't determine distribution version. Please specify it
explicitly via 'version' in Makefile.PL, or set a valid $VERSION
in a module, and provide its file path via 'version_from' (or
'all_from' if you prefer) in Makefile.PL.
EOT
if ( $self->tests ) {
my @tests = split ' ', $self->tests;
my %seen;
$args->{test} = {
TESTS => (join ' ', grep {!$seen{$_}++} @tests),
};
} elsif ( $Module::Install::ExtraTests::use_extratests ) {
# Module::Install::ExtraTests doesn't set $self->tests and does its own tests via harness.
# So, just ignore our xt tests here.
} elsif ( -d 'xt' and ($Module::Install::AUTHOR or $ENV{RELEASE_TESTING}) ) {
$args->{test} = {
TESTS => join( ' ', map { "$_/*.t" } grep { -d $_ } qw{ t xt } ),
};
}
if ( $] >= 5.005 ) {
$args->{ABSTRACT} = $self->abstract;
$args->{AUTHOR} = join ', ', @{$self->author || []};
}
if ( $self->makemaker(6.10) ) {
$args->{NO_META} = 1;
#$args->{NO_MYMETA} = 1;
}
if ( $self->makemaker(6.17) and $self->sign ) {
$args->{SIGN} = 1;
}
unless ( $self->is_admin ) {
delete $args->{SIGN};
}
if ( $self->makemaker(6.31) and $self->license ) {
$args->{LICENSE} = $self->license;
}
my $prereq = ($args->{PREREQ_PM} ||= {});
%$prereq = ( %$prereq,
map { @$_ } # flatten [module => version]
map { @$_ }
grep $_,
($self->requires)
);
# Remove any reference to perl, PREREQ_PM doesn't support it
delete $args->{PREREQ_PM}->{perl};
# Merge both kinds of requires into BUILD_REQUIRES
my $build_prereq = ($args->{BUILD_REQUIRES} ||= {});
%$build_prereq = ( %$build_prereq,
map { @$_ } # flatten [module => version]
map { @$_ }
grep $_,
($self->configure_requires, $self->build_requires)
);
# Remove any reference to perl, BUILD_REQUIRES doesn't support it
delete $args->{BUILD_REQUIRES}->{perl};
# Delete bundled dists from prereq_pm, add it to Makefile DIR
my $subdirs = ($args->{DIR} || []);
if ($self->bundles) {
my %processed;
foreach my $bundle (@{ $self->bundles }) {
my ($mod_name, $dist_dir) = @$bundle;
delete $prereq->{$mod_name};
$dist_dir = File::Basename::basename($dist_dir); # dir for building this module
if (not exists $processed{$dist_dir}) {
if (-d $dist_dir) {
# List as sub-directory to be processed by make
push @$subdirs, $dist_dir;
}
# Else do nothing: the module is already present on the system
$processed{$dist_dir} = undef;
}
}
}
unless ( $self->makemaker('6.55_03') ) {
%$prereq = (%$prereq,%$build_prereq);
delete $args->{BUILD_REQUIRES};
}
if ( my $perl_version = $self->perl_version ) {
eval "use $perl_version; 1"
or die "ERROR: perl: Version $] is installed, "
. "but we need version >= $perl_version";
if ( $self->makemaker(6.48) ) {
$args->{MIN_PERL_VERSION} = $perl_version;
}
}
if ($self->installdirs) {
warn qq{old INSTALLDIRS (probably set by makemaker_args) is overriden by installdirs\n} if $args->{INSTALLDIRS};
$args->{INSTALLDIRS} = $self->installdirs;
}
my %args = map {
( $_ => $args->{$_} ) } grep {defined($args->{$_} )
} keys %$args;
my $user_preop = delete $args{dist}->{PREOP};
if ( my $preop = $self->admin->preop($user_preop) ) {
foreach my $key ( keys %$preop ) {
$args{dist}->{$key} = $preop->{$key};
}
}
my $mm = ExtUtils::MakeMaker::WriteMakefile(%args);
$self->fix_up_makefile($mm->{FIRST_MAKEFILE} || 'Makefile');
}
sub fix_up_makefile {
my $self = shift;
my $makefile_name = shift;
my $top_class = ref($self->_top) || '';
my $top_version = $self->_top->VERSION || '';
my $preamble = $self->preamble
? "# Preamble by $top_class $top_version\n"
. $self->preamble
: '';
my $postamble = "# Postamble by $top_class $top_version\n"
. ($self->postamble || '');
local *MAKEFILE;
open MAKEFILE, "+< $makefile_name" or die "fix_up_makefile: Couldn't open $makefile_name: $!";
eval { flock MAKEFILE, LOCK_EX };
my $makefile = do { local $/; };
$makefile =~ s/\b(test_harness\(\$\(TEST_VERBOSE\), )/$1'inc', /;
$makefile =~ s/( -I\$\(INST_ARCHLIB\))/ -Iinc$1/g;
$makefile =~ s/( "-I\$\(INST_LIB\)")/ "-Iinc"$1/g;
$makefile =~ s/^(FULLPERL = .*)/$1 "-Iinc"/m;
$makefile =~ s/^(PERL = .*)/$1 "-Iinc"/m;
# Module::Install will never be used to build the Core Perl
# Sometimes PERL_LIB and PERL_ARCHLIB get written anyway, which breaks
# PREFIX/PERL5LIB, and thus, install_share. Blank them if they exist
$makefile =~ s/^PERL_LIB = .+/PERL_LIB =/m;
#$makefile =~ s/^PERL_ARCHLIB = .+/PERL_ARCHLIB =/m;
# Perl 5.005 mentions PERL_LIB explicitly, so we have to remove that as well.
$makefile =~ s/(\"?)-I\$\(PERL_LIB\)\1//g;
# XXX - This is currently unused; not sure if it breaks other MM-users
# $makefile =~ s/^pm_to_blib\s+:\s+/pm_to_blib :: /mg;
seek MAKEFILE, 0, SEEK_SET;
truncate MAKEFILE, 0;
print MAKEFILE "$preamble$makefile$postamble" or die $!;
close MAKEFILE or die $!;
1;
}
sub preamble {
my ($self, $text) = @_;
$self->{preamble} = $text . $self->{preamble} if defined $text;
$self->{preamble};
}
sub postamble {
my ($self, $text) = @_;
$self->{postamble} ||= $self->admin->postamble;
$self->{postamble} .= $text if defined $text;
$self->{postamble}
}
1;
__END__
#line 544
IRI-0.013/inc/Module/Install/Base.pm 000644 000765 000024 00000002147 14676277375 017077 0 ustar 00greg staff 000000 000000 #line 1
package Module::Install::Base;
use strict 'vars';
use vars qw{$VERSION};
BEGIN {
$VERSION = '1.21';
}
# Suspend handler for "redefined" warnings
BEGIN {
my $w = $SIG{__WARN__};
$SIG{__WARN__} = sub { $w };
}
#line 42
sub new {
my $class = shift;
unless ( defined &{"${class}::call"} ) {
*{"${class}::call"} = sub { shift->_top->call(@_) };
}
unless ( defined &{"${class}::load"} ) {
*{"${class}::load"} = sub { shift->_top->load(@_) };
}
bless { @_ }, $class;
}
#line 61
sub AUTOLOAD {
local $@;
my $func = eval { shift->_top->autoload } or return;
goto &$func;
}
#line 75
sub _top {
$_[0]->{_top};
}
#line 90
sub admin {
$_[0]->_top->{admin}
or
Module::Install::Base::FakeAdmin->new;
}
#line 106
sub is_admin {
! $_[0]->admin->isa('Module::Install::Base::FakeAdmin');
}
sub DESTROY {}
package Module::Install::Base::FakeAdmin;
use vars qw{$VERSION};
BEGIN {
$VERSION = $Module::Install::Base::VERSION;
}
my $fake;
sub new {
$fake ||= bless(\@_, $_[0]);
}
sub AUTOLOAD {}
sub DESTROY {}
# Restore warning handler
BEGIN {
$SIG{__WARN__} = $SIG{__WARN__}->();
}
1;
#line 159