Linux-Inotify2-2.3/ 0000755 0000000 0000000 00000000000 14101233777 012661 5 ustar root root Linux-Inotify2-2.3/MANIFEST 0000644 0000000 0000000 00000000432 14101233777 014011 0 ustar root root README
MANIFEST
COPYING
Changes
Makefile.PL
Inotify2.pm
Inotify2.xs
eg/simple
eg/event
t/00_load.t
t/01_inotify.t
META.yml Module YAML meta-data (added by MakeMaker)
META.json Module JSON meta-data (added by MakeMaker)
Linux-Inotify2-2.3/eg/ 0000755 0000000 0000000 00000000000 14101233777 013254 5 ustar root root Linux-Inotify2-2.3/eg/event 0000755 0000000 0000000 00000001157 10302504073 014314 0 ustar root root #!/opt/bin/perl
# example for Event integration
use Event;
use Linux::Inotify2;
my $inotify = new Linux::Inotify2;
Event->io (fd => $inotify->fileno, poll => 'r', cb => sub { $inotify->poll });
$inotify->watch ("/tmp", IN_ALL_EVENTS, sub {
my $e = shift;
printf "events for <%s>:%d received: %x\n", $e->fullname, $e->cookie, $e->mask;
print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
});
Event::loop;
Linux-Inotify2-2.3/eg/simple 0000755 0000000 0000000 00000001070 10302504133 014453 0 ustar root root #!/opt/bin/perl
# very simple example without further modules
use Linux::Inotify2;
my $inotify = new Linux::Inotify2;
$inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
my $e = shift;
printf "events for <%s> received: %s\n", $e->fullname, $e->mask;
print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
$e->w->cancel;
});
$inotify->poll;
Linux-Inotify2-2.3/Changes 0000644 0000000 0000000 00000006430 14101233770 014150 0 ustar root root Revision history for Linux::Inotify2
TODO: document move/renaming issues for fullname
TODO: find_watchers($path), or maybe just ->watchers
2.3 Sat Jul 31 13:45:51 CEST 2021
- store a filehandle internally so it gets perl's CLOEXEC flag as needed. also
gets rid of the destructor and the internal close function for added space
savings (reported by Eric Wong).
- add new ->fh accessor.
2.2 Mon Dec 9 04:09:05 CET 2019
- define IN_EXCL_UNLINK to 0 if it is missing, for the benefit of
antique systems that lack this symbol.
2.1 Fri Oct 26 03:16:03 CEST 2018
- damn, left debugging code not caught by tests (reported by losyme).
2.0 Thu Oct 25 03:19:08 CEST 2018
- fix poll and read documentation w.r.t. errors - this changes the
documented API, but is how the module has always behaved.
- mention https://lwn.net/Articles/605128/ in the docs.
- new on_overflow callback, called for overflow events.
- new ->broadcast method that calls all watchers with some event.
- automatically broadcast overflow events to all watchers by default.
- read now returns all events (except ignored ones), not just ones
it has registered watchers for (e.g. overflow events).
- reduced dependencies (Mike Pomraning).
- add IN_EXCL_UNLINK flag.
- more efficient constant initialisation.
1.22 Tue Jun 14 08:34:38 CEST 2011
- use a more useful definition of IN_xxx methods - any bits, not
a match. (pointed out by Anatoliy Grishayev).
- slightly reworked the documentation.
1.21 Mon Sep 21 10:07:07 CEST 2009
- fix a couple of typoes, as pointed out by Grant McLean.
- rely on common::sense for stricter namespace checking.
1.2 Tue Oct 7 19:23:57 CEST 2008
- include IN_DELETE_SELF in events that cancel watchers, as
the kernel seems to handle it this way only.
- require sys/inotify.h to be installed, remove the local
copy (patch by Adrian Bunk).
- update examples.
1.1 Fri Sep 29 16:40:14 CEST 2006
- fixed formatting.
- add IN_MASK_ADD, IN_DONT_FOLLOW, IN_ONLYDIR.
- updated inotify.h from inotify-utils for wider architecture support.
- no internal changes.
1.01 Tue Dec 20 12:31:16 CET 2005
- more fixes by Andrejs Dubovskis:
- removed debugging code accidentally left in.
- streaming API didn't always return properly blessed objects.
1.0 Mon Dec 19 17:48:01 CET 2005
- incorporated a major patch by Andrejs Dubovskis:
- added a non-callback interface to read events
- better error handling in non-blocking case.
- added test case.
- fix reading events leaking memory.
0.8 Sun Nov 27 13:43:14 CET 2005
- improved documentation.
- added IN_MOVE_SELF.
- cancel events when receiving an IN_ONESHOT event.
- clarify documentation for ->cookie.
0.2 Tue Aug 23 04:27:31 CEST 2005
- poll now really returns the #events.
- handle multiple cancel's gracefully.
- auto-cancel watchers on IN_IGNORED and IN_UNMOUNT.
situation with IN_ONESHOT is unclear
(does have no effect on 2.6.13-rc6-git13).
- avoid race between canceled and newly-created watches.
- improved documentation.
0.1 Mon Aug 22 12:05:15 CEST 2005
- original version, a Linux::AIO clone.
Linux-Inotify2-2.3/COPYING 0000644 0000000 0000000 00000000076 10211640730 013704 0 ustar root root This module is licensed under the same terms as perl itself.
Linux-Inotify2-2.3/Inotify2.pm 0000644 0000000 0000000 00000032617 14100303353 014716 0 ustar root root =head1 NAME
Linux::Inotify2 - scalable directory/file change notification
=head1 SYNOPSIS
=head2 Callback Interface
use Linux::Inotify2;
# create a new object
my $inotify = new Linux::Inotify2
or die "unable to create new inotify object: $!";
# add watchers
$inotify->watch ("/etc/passwd", IN_ACCESS, sub {
my $e = shift;
my $name = $e->fullname;
print "$name was accessed\n" if $e->IN_ACCESS;
print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
print "$name is gone\n" if $e->IN_IGNORED;
print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
# cancel this watcher: remove no further events
$e->w->cancel;
});
# integration into AnyEvent (works with EV, Glib, Tk, POE...)
my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };
# manual event loop
$inotify->poll while 1;
=head2 Streaming Interface
use Linux::Inotify2;
# create a new object
my $inotify = new Linux::Inotify2
or die "Unable to create new inotify object: $!";
# create watch
$inotify->watch ("/etc/passwd", IN_ACCESS)
or die "watch creation failed";
while () {
my @events = $inotify->read;
printf "mask\t%d\n", $_->mask foreach @events;
}
=head1 DESCRIPTION
This module implements an interface to the Linux 2.6.13 and later Inotify
file/directory change notification system.
It has a number of advantages over the Linux::Inotify module:
- it is portable (Linux::Inotify only works on x86)
- the equivalent of fullname works correctly
- it is better documented
- it has callback-style interface, which is better suited for
integration.
As for the inotify API itself - it is a very tricky, and somewhat
unreliable API. For a good overview of the challenges you might run into,
see this LWN article: L.
=head2 The Linux::Inotify2 Class
=over 4
=cut
package Linux::Inotify2;
use Scalar::Util ();
use common::sense;
use Exporter qw(import);
BEGIN {
our $VERSION = '2.3';
our @EXPORT = qw(
IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
IN_ALL_EVENTS
IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
IN_CLOSE IN_MOVE
IN_ISDIR IN_ONESHOT IN_MASK_ADD
IN_DONT_FOLLOW IN_EXCL_UNLINK IN_ONLYDIR
);
require XSLoader;
XSLoader::load Linux::Inotify2, $VERSION;
}
=item my $inotify = new Linux::Inotify2
Create a new notify object and return it. A notify object is kind of a
container that stores watches on file system names and is responsible for
handling event data.
On error, C is returned and C<$!> will be set accordingly. The
following errors are documented:
ENFILE The system limit on the total number of file descriptors has been reached.
EMFILE The user limit on the total number of inotify instances has been reached.
ENOMEM Insufficient kernel memory is available.
Example:
my $inotify = new Linux::Inotify2
or die "Unable to create new inotify object: $!";
=cut
sub new {
my ($class) = @_;
my $fd = inotify_init;
return unless $fd >= 0;
open my $fh, "<&=", $fd
or die "cannot open fd $fd as perl handle\n";
bless { fd => $fd, fh => $fh }, $class
}
=item $watch = $inotify->watch ($name, $mask[, $cb])
Add a new watcher to the given notifier. The watcher will create events
on the pathname C<$name> as given in C<$mask>, which can be any of the
following constants (all exported by default) ORed together. Constants
unavailable on your system will evaluate to C<0>.
"file" refers to any file system object in the watched object (always a
directory), that is files, directories, symlinks, device nodes etc., while
"object" refers to the object the watcher has been set on itself:
IN_ACCESS object was accessed
IN_MODIFY object was modified
IN_ATTRIB object metadata changed
IN_CLOSE_WRITE writable fd to file / to object was closed
IN_CLOSE_NOWRITE readonly fd to file / to object closed
IN_OPEN object was opened
IN_MOVED_FROM file was moved from this object (directory)
IN_MOVED_TO file was moved to this object (directory)
IN_CREATE file was created in this object (directory)
IN_DELETE file was deleted from this object (directory)
IN_DELETE_SELF object itself was deleted
IN_MOVE_SELF object itself was moved
IN_ALL_EVENTS all of the above events
IN_ONESHOT only send event once
IN_ONLYDIR only watch the path if it is a directory
IN_DONT_FOLLOW don't follow a sym link (Linux 2.6.15+)
IN_EXCL_UNLINK don't create events for unlinked objects (Linux 2.6.36+)
IN_MASK_ADD not supported with the current version of this module
IN_CLOSE same as IN_CLOSE_WRITE | IN_CLOSE_NOWRITE
IN_MOVE same as IN_MOVED_FROM | IN_MOVED_TO
C<$cb> is a perl code reference that, if given, is called for each
event. It receives a C object.
The returned C<$watch> object is of class C.
On error, C is returned and C<$!> will be set accordingly. The
following errors are documented:
EBADF The given file descriptor is not valid.
EINVAL The given event mask contains no legal events.
ENOMEM Insufficient kernel memory was available.
ENOSPC The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
EACCESS Read access to the given file is not permitted.
Example, show when C gets accessed and/or modified once:
$inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
my $e = shift;
print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
$e->w->cancel;
});
=cut
sub watch {
my ($self, $name, $mask, $cb) = @_;
my $wd = inotify_add_watch $self->{fd}, $name, $mask;
return unless $wd >= 0;
my $w = $self->{w}{$wd} = bless {
inotify => $self,
wd => $wd,
name => $name,
mask => $mask,
cb => $cb,
}, "Linux::Inotify2::Watch";
Scalar::Util::weaken $w->{inotify};
$w
}
=item $inotify->fileno
Returns the file descriptor for this notify object. When in non-blocking
mode, you are responsible for calling the C method when this file
descriptor becomes ready for reading.
=item $inotify->fh
Similar to C, but returns a perl file handle instead.
=cut
sub fileno {
$_[0]{fd}
}
sub fh {
$_[0]{fh}
}
=item $inotify->blocking ($blocking)
Clears ($blocking true) or sets ($blocking false) the C flag on the file descriptor.
=cut
sub blocking {
my ($self, $blocking) = @_;
inotify_blocking $self->{fd}, $blocking;
}
=item $count = $inotify->poll
Reads events from the kernel and handles them. If the notify file
descriptor is blocking (the default), then this method waits for at least
one event. Otherwise it returns immediately when no pending events could
be read.
Returns the count of events that have been handled (which can be C<0> in case
events have been received but have been ignored or handled internally).
Croaks when an error occurs.
=cut
sub poll {
scalar &read
}
=item @events = $inotify->read
Reads events from the kernel. Blocks when the file descriptor is in
blocking mode (default) until any event arrives. Returns list of
C objects or empty list if none (non-blocking
mode or events got ignored).
Croaks on error.
Normally you shouldn't use this function, but instead use watcher
callbacks and call C<< ->poll >>.
=cut
sub read {
my ($self) = @_;
my @ev = inotify_read $self->{fd};
my @res;
for (@ev) {
exists $self->{ignore}{$_->{wd}}
and next; # watcher has been canceled
push @res, bless $_, "Linux::Inotify2::Event";
my $w = $_->{w} = $self->{w}{$_->{wd}}
or do {
# no such watcher, but maybe we can do overflow handling
if ($_->{mask} & IN_Q_OVERFLOW) {
if ($self->{on_overflow}) {
$self->{on_overflow}($_);
} else {
$self->broadcast ($_);
}
}
next;
};
$w->{cb}($_) if $w->{cb};
$w->cancel if $_->{mask} & (IN_IGNORED | IN_UNMOUNT | IN_ONESHOT | IN_DELETE_SELF);
}
delete $self->{ignore};
wantarray ? @res : scalar @res
}
=item $inotify->on_overflow ($cb->($ev))
Sets the callback to be used for overflow handling
(default: C): When C receives an event with C
set, it will invoke this callback with the event.
When the callback is C, then it broadcasts the event to all
registered watchers, i.e., C is equivalent to:
sub { $inotify->broadcast ($_[0]) }
=cut
sub on_overflow {
my $prev = $_[0]{on_overflow};
$_[0]{on_overflow} = $_[1]
if @_ >= 2;
$prev
}
=item $inotify->broadcast ($ev)
Invokes all registered watcher callbacks and passes the given event to
them. Most useful in overflow handlers.
=cut
sub broadcast {
my ($self, $ev) = @_;
for my $w (values %{ $self->{w} }) {
local $ev->{w} = $w;
$w->{cb}($ev) if $w->{cb};
}
}
=back
=head2 The Linux::Inotify2::Event Class
Objects of this class are handed as first argument to the watcher
callback. It has the following members and methods:
=over 4
=item $event->w
=item $event->{w}
The watcher object for this event, if one is available. Generally, you cna
only rely on the value of this member inside watcher callbacks.
=item $event->name
=item $event->{name}
The path of the file system object, relative to the watched name.
=item $event->fullname
Returns the "full" name of the relevant object, i.e. including the C
member of the watcher (if the watch object is on a directory and a
directory entry is affected), or simply the C member itself when the
object is the watch object itself.
This call requires C<< $event->{w} >> to be valid, which is generally only
the case within watcher callbacks.
=item $event->mask
=item $event->{mask}
The received event mask. In addition to the events described for C<<
$inotify->watch >>, the following flags (exported by default) can be set:
IN_ISDIR event object is a directory
IN_Q_OVERFLOW event queue overflowed
# when any of the following flags are set,
# then watchers for this event are automatically canceled
IN_UNMOUNT filesystem for watched object was unmounted
IN_IGNORED file was ignored/is gone (no more events are delivered)
IN_ONESHOT only one event was generated
IN_Q_OVERFLOW queue overflow - event might not be specific to a watcher
=item $event->IN_xxx
Returns a boolean that returns true if the event mask contains any events
specified by the mask. All of the C constants can be used as
methods.
=item $event->cookie
=item $event->{cookie}
The event cookie to "synchronize two events". Normally zero, this value is
set when two events relating to the same file are generated. As far as I
know, this only happens for C and C events, to
identify the old and new name of a file.
Note that the inotify API makes it impossible to know whether there will
be a C event - you might receive only one of the events,
and even if you receive both, there might be any number of events in
between. The best approach seems to be to implement a small timeout
after C to see if a matching C event will be
received - 2ms seem to work relatively well.
=back
=cut
package Linux::Inotify2::Event;
sub w { $_[0]{w} }
sub name { $_[0]{name} }
sub mask { $_[0]{mask} }
sub cookie { $_[0]{cookie} }
sub fullname {
length $_[0]{name}
? "$_[0]{w}{name}/$_[0]{name}"
: $_[0]{w}{name};
}
for my $name (@Linux::Inotify2::EXPORT) {
my $mask = &{"Linux::Inotify2::$name"};
*$name = sub { $_[0]{mask} & $mask };
}
=head2 The Linux::Inotify2::Watch Class
Watcher objects are created by calling the C method of a notifier.
It has the following members and methods:
=over 4
=item $watch->name
=item $watch->{name}
The name as specified in the C call. For the object itself, this is
the empty string. For directory watches, this is the name of the entry
without leading path elements.
=item $watch->mask
=item $watch->{mask}
The mask as specified in the C call.
=item $watch->cb ([new callback])
=item $watch->{cb}
The callback as specified in the C call. Can optionally be changed.
=item $watch->cancel
Cancels/removes this watcher. Future events, even if already queued queued,
will not be handled and resources will be freed.
=back
=cut
package Linux::Inotify2::Watch;
sub name { $_[0]{name} }
sub mask { $_[0]{mask} }
sub cb {
$_[0]{cb} = $_[1] if @_ > 1;
$_[0]{cb}
}
sub cancel {
my ($self) = @_;
my $inotify = delete $self->{inotify}
or return 1; # already canceled
delete $inotify->{w}{$self->{wd}}; # we are no longer there
$inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll
(Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
? 1 : undef
}
=head1 SEE ALSO
L, L.
=head1 AUTHOR
Marc Lehmann
http://home.schmorp.de/
=cut
1
Linux-Inotify2-2.3/t/ 0000755 0000000 0000000 00000000000 14101233777 013124 5 ustar root root Linux-Inotify2-2.3/t/01_inotify.t 0000644 0000000 0000000 00000000747 10351765707 015310 0 ustar root root use Test::Simple tests => 5;
use Linux::Inotify2;
my $in = Linux::Inotify2->new;
ok ($in, "inotify handle created");
# create directory for watch
mkdir $$;
my $watch = $in->watch ($$, IN_ALL_EVENTS);
ok ($watch, "watch created for directory $$");
$in->blocking (0);
{
my @list = $in->read;
ok (@list==0, "non blocking: $!");
}
rmdir $$;
{
my @list = $in->poll;
ok (@list > 0, scalar @list . " events read");
}
ok ($watch->cancel, "watch canceled");
END {
rmdir $$;
}
Linux-Inotify2-2.3/t/00_load.t 0000644 0000000 0000000 00000000175 10302321002 014504 0 ustar root root BEGIN { $| = 1; print "1..1\n"; }
END {print "not ok 1\n" unless $loaded;}
use Linux::Inotify2;
$loaded = 1;
print "ok 1\n";
Linux-Inotify2-2.3/Inotify2.xs 0000644 0000000 0000000 00000006102 14100302570 014722 0 ustar root root #define PERL_NO_GET_CONTEXT
#include "EXTERN.h"
#include "perl.h"
#include "XSUB.h"
#include
#include
#include
#ifndef IN_EXCL_UNLINK
#define IN_EXCL_UNLINK 0
#endif
MODULE = Linux::Inotify2 PACKAGE = Linux::Inotify2
PROTOTYPES: ENABLE
BOOT:
{
HV *stash = GvSTASH (CvGV (cv));
static const struct civ { const char *name; IV iv; } *civ, const_iv[] = {
{ "IN_ACCESS" , IN_ACCESS },
{ "IN_MODIFY" , IN_MODIFY },
{ "IN_ATTRIB" , IN_ATTRIB },
{ "IN_CLOSE_WRITE" , IN_CLOSE_WRITE },
{ "IN_CLOSE_NOWRITE", IN_CLOSE_NOWRITE },
{ "IN_OPEN" , IN_OPEN },
{ "IN_MOVED_FROM" , IN_MOVED_FROM },
{ "IN_MOVED_TO" , IN_MOVED_TO },
{ "IN_CREATE" , IN_CREATE },
{ "IN_DELETE" , IN_DELETE },
{ "IN_DELETE_SELF" , IN_DELETE_SELF },
{ "IN_MOVE_SELF" , IN_MOVE_SELF },
{ "IN_UNMOUNT" , IN_UNMOUNT },
{ "IN_Q_OVERFLOW" , IN_Q_OVERFLOW },
{ "IN_IGNORED" , IN_IGNORED },
{ "IN_CLOSE" , IN_CLOSE },
{ "IN_MOVE" , IN_MOVE },
{ "IN_ONLYDIR" , IN_ONLYDIR },
{ "IN_DONT_FOLLOW" , IN_DONT_FOLLOW },
{ "IN_EXCL_UNLINK" , IN_EXCL_UNLINK },
{ "IN_MASK_ADD" , IN_MASK_ADD },
{ "IN_ISDIR" , IN_ISDIR },
{ "IN_ONESHOT" , IN_ONESHOT },
{ "IN_ALL_EVENTS" , IN_ALL_EVENTS },
};
for (civ = const_iv + sizeof (const_iv) / sizeof (const_iv [0]); civ > const_iv; civ--)
newCONSTSUB (stash, (char *)civ[-1].name, newSViv (civ[-1].iv));
}
int
inotify_init ()
int
inotify_add_watch (int fd, char *name, U32 mask)
int
inotify_rm_watch (int fd, U32 wd)
int
inotify_blocking (int fd, I32 blocking)
CODE:
fcntl (fd, F_SETFL, blocking ? 0 : O_NONBLOCK);
void
inotify_read (int fd, int size = 8192)
PPCODE:
{
char buf [size], *cur, *end;
int got = read (fd, buf, size);
if (got < 0)
if (errno != EAGAIN && errno != EINTR)
croak ("Linux::Inotify2: read error while reading events");
else
XSRETURN_EMPTY;
cur = buf;
end = buf + got;
while (cur < end)
{
struct inotify_event *ev = (struct inotify_event *)cur;
cur += sizeof (struct inotify_event) + ev->len;
while (ev->len > 0 && !ev->name [ev->len - 1])
--ev->len;
HV *hv = newHV ();
hv_store (hv, "wd", sizeof ("wd") - 1, newSViv (ev->wd), 0);
hv_store (hv, "mask", sizeof ("mask") - 1, newSViv (ev->mask), 0);
hv_store (hv, "cookie", sizeof ("cookie") - 1, newSViv (ev->cookie), 0);
hv_store (hv, "name", sizeof ("name") - 1, newSVpvn (ev->name, ev->len), 0);
XPUSHs (sv_2mortal (newRV_noinc ((SV *)hv)));
}
}
Linux-Inotify2-2.3/README 0000644 0000000 0000000 00000026100 14101233777 013540 0 ustar root root NAME
Linux::Inotify2 - scalable directory/file change notification
SYNOPSIS
Callback Interface
use Linux::Inotify2;
# create a new object
my $inotify = new Linux::Inotify2
or die "unable to create new inotify object: $!";
# add watchers
$inotify->watch ("/etc/passwd", IN_ACCESS, sub {
my $e = shift;
my $name = $e->fullname;
print "$name was accessed\n" if $e->IN_ACCESS;
print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
print "$name is gone\n" if $e->IN_IGNORED;
print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
# cancel this watcher: remove no further events
$e->w->cancel;
});
# integration into AnyEvent (works with EV, Glib, Tk, POE...)
my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };
# manual event loop
$inotify->poll while 1;
Streaming Interface
use Linux::Inotify2;
# create a new object
my $inotify = new Linux::Inotify2
or die "Unable to create new inotify object: $!";
# create watch
$inotify->watch ("/etc/passwd", IN_ACCESS)
or die "watch creation failed";
while () {
my @events = $inotify->read;
printf "mask\t%d\n", $_->mask foreach @events;
}
DESCRIPTION
This module implements an interface to the Linux 2.6.13 and later
Inotify file/directory change notification system.
It has a number of advantages over the Linux::Inotify module:
- it is portable (Linux::Inotify only works on x86)
- the equivalent of fullname works correctly
- it is better documented
- it has callback-style interface, which is better suited for
integration.
As for the inotify API itself - it is a very tricky, and somewhat
unreliable API. For a good overview of the challenges you might run
into, see this LWN article: .
The Linux::Inotify2 Class
my $inotify = new Linux::Inotify2
Create a new notify object and return it. A notify object is kind of
a container that stores watches on file system names and is
responsible for handling event data.
On error, "undef" is returned and $! will be set accordingly. The
following errors are documented:
ENFILE The system limit on the total number of file descriptors has been reached.
EMFILE The user limit on the total number of inotify instances has been reached.
ENOMEM Insufficient kernel memory is available.
Example:
my $inotify = new Linux::Inotify2
or die "Unable to create new inotify object: $!";
$watch = $inotify->watch ($name, $mask[, $cb])
Add a new watcher to the given notifier. The watcher will create
events on the pathname $name as given in $mask, which can be any of
the following constants (all exported by default) ORed together.
Constants unavailable on your system will evaluate to 0.
"file" refers to any file system object in the watched object
(always a directory), that is files, directories, symlinks, device
nodes etc., while "object" refers to the object the watcher has been
set on itself:
IN_ACCESS object was accessed
IN_MODIFY object was modified
IN_ATTRIB object metadata changed
IN_CLOSE_WRITE writable fd to file / to object was closed
IN_CLOSE_NOWRITE readonly fd to file / to object closed
IN_OPEN object was opened
IN_MOVED_FROM file was moved from this object (directory)
IN_MOVED_TO file was moved to this object (directory)
IN_CREATE file was created in this object (directory)
IN_DELETE file was deleted from this object (directory)
IN_DELETE_SELF object itself was deleted
IN_MOVE_SELF object itself was moved
IN_ALL_EVENTS all of the above events
IN_ONESHOT only send event once
IN_ONLYDIR only watch the path if it is a directory
IN_DONT_FOLLOW don't follow a sym link (Linux 2.6.15+)
IN_EXCL_UNLINK don't create events for unlinked objects (Linux 2.6.36+)
IN_MASK_ADD not supported with the current version of this module
IN_CLOSE same as IN_CLOSE_WRITE | IN_CLOSE_NOWRITE
IN_MOVE same as IN_MOVED_FROM | IN_MOVED_TO
$cb is a perl code reference that, if given, is called for each
event. It receives a "Linux::Inotify2::Event" object.
The returned $watch object is of class "Linux::Inotify2::Watch".
On error, "undef" is returned and $! will be set accordingly. The
following errors are documented:
EBADF The given file descriptor is not valid.
EINVAL The given event mask contains no legal events.
ENOMEM Insufficient kernel memory was available.
ENOSPC The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
EACCESS Read access to the given file is not permitted.
Example, show when "/etc/passwd" gets accessed and/or modified once:
$inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
my $e = shift;
print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
$e->w->cancel;
});
$inotify->fileno
Returns the file descriptor for this notify object. When in
non-blocking mode, you are responsible for calling the "poll" method
when this file descriptor becomes ready for reading.
$inotify->fh
Similar to "fileno", but returns a perl file handle instead.
$inotify->blocking ($blocking)
Clears ($blocking true) or sets ($blocking false) the "O_NONBLOCK"
flag on the file descriptor.
$count = $inotify->poll
Reads events from the kernel and handles them. If the notify file
descriptor is blocking (the default), then this method waits for at
least one event. Otherwise it returns immediately when no pending
events could be read.
Returns the count of events that have been handled (which can be 0
in case events have been received but have been ignored or handled
internally).
Croaks when an error occurs.
@events = $inotify->read
Reads events from the kernel. Blocks when the file descriptor is in
blocking mode (default) until any event arrives. Returns list of
"Linux::Inotify2::Event" objects or empty list if none (non-blocking
mode or events got ignored).
Croaks on error.
Normally you shouldn't use this function, but instead use watcher
callbacks and call "->poll".
$inotify->on_overflow ($cb->($ev))
Sets the callback to be used for overflow handling (default:
"undef"): When "read" receives an event with "IN_Q_OVERFLOW" set, it
will invoke this callback with the event.
When the callback is "undef", then it broadcasts the event to all
registered watchers, i.e., "undef" is equivalent to:
sub { $inotify->broadcast ($_[0]) }
$inotify->broadcast ($ev)
Invokes all registered watcher callbacks and passes the given event
to them. Most useful in overflow handlers.
The Linux::Inotify2::Event Class
Objects of this class are handed as first argument to the watcher
callback. It has the following members and methods:
$event->w
$event->{w}
The watcher object for this event, if one is available. Generally,
you cna only rely on the value of this member inside watcher
callbacks.
$event->name
$event->{name}
The path of the file system object, relative to the watched name.
$event->fullname
Returns the "full" name of the relevant object, i.e. including the
"name" member of the watcher (if the watch object is on a directory
and a directory entry is affected), or simply the "name" member
itself when the object is the watch object itself.
This call requires "$event->{w}" to be valid, which is generally
only the case within watcher callbacks.
$event->mask
$event->{mask}
The received event mask. In addition to the events described for
"$inotify->watch", the following flags (exported by default) can be
set:
IN_ISDIR event object is a directory
IN_Q_OVERFLOW event queue overflowed
# when any of the following flags are set,
# then watchers for this event are automatically canceled
IN_UNMOUNT filesystem for watched object was unmounted
IN_IGNORED file was ignored/is gone (no more events are delivered)
IN_ONESHOT only one event was generated
IN_Q_OVERFLOW queue overflow - event might not be specific to a watcher
$event->IN_xxx
Returns a boolean that returns true if the event mask contains any
events specified by the mask. All of the "IN_xxx" constants can be
used as methods.
$event->cookie
$event->{cookie}
The event cookie to "synchronize two events". Normally zero, this
value is set when two events relating to the same file are
generated. As far as I know, this only happens for "IN_MOVED_FROM"
and "IN_MOVED_TO" events, to identify the old and new name of a
file.
Note that the inotify API makes it impossible to know whether there
will be a "IN_MOVED_TO" event - you might receive only one of the
events, and even if you receive both, there might be any number of
events in between. The best approach seems to be to implement a
small timeout after "IN_MOVED_FROM" to see if a matching
"IN_MOVED_TO" event will be received - 2ms seem to work relatively
well.
The Linux::Inotify2::Watch Class
Watcher objects are created by calling the "watch" method of a notifier.
It has the following members and methods:
$watch->name
$watch->{name}
The name as specified in the "watch" call. For the object itself,
this is the empty string. For directory watches, this is the name of
the entry without leading path elements.
$watch->mask
$watch->{mask}
The mask as specified in the "watch" call.
$watch->cb ([new callback])
$watch->{cb}
The callback as specified in the "watch" call. Can optionally be
changed.
$watch->cancel
Cancels/removes this watcher. Future events, even if already queued
queued, will not be handled and resources will be freed.
SEE ALSO
AnyEvent, Linux::Inotify.
AUTHOR
Marc Lehmann
http://home.schmorp.de/
Linux-Inotify2-2.3/Makefile.PL 0000644 0000000 0000000 00000000602 11255632164 014631 0 ustar root root use ExtUtils::MakeMaker;
my $mm = MM->new({
dist => {
PREOP => 'pod2text Inotify2.pm | tee README >$(DISTVNAME)/README; chmod -R u=rwX,go=rX . ;',
COMPRESS => 'gzip -9v',
SUFFIX => '.gz',
},
NAME => "Linux::Inotify2",
VERSION_FROM => "Inotify2.pm",
PREREQ_PM => {
common::sense => 0,
},
});
$mm->flush;
Linux-Inotify2-2.3/META.yml 0000644 0000000 0000000 00000000707 14101233777 014136 0 ustar root root ---
abstract: unknown
author:
- unknown
build_requires:
ExtUtils::MakeMaker: '0'
configure_requires:
ExtUtils::MakeMaker: '0'
dynamic_config: 1
generated_by: 'ExtUtils::MakeMaker version 7.34, CPAN::Meta::Converter version 2.150001'
license: unknown
meta-spec:
url: http://module-build.sourceforge.net/META-spec-v1.4.html
version: '1.4'
name: Linux-Inotify2
no_index:
directory:
- t
- inc
requires:
common::sense: '0'
version: '2.3'
Linux-Inotify2-2.3/META.json 0000644 0000000 0000000 00000001503 14101233777 014301 0 ustar root root {
"abstract" : "unknown",
"author" : [
"unknown"
],
"dynamic_config" : 1,
"generated_by" : "ExtUtils::MakeMaker version 7.34, CPAN::Meta::Converter version 2.150001",
"license" : [
"unknown"
],
"meta-spec" : {
"url" : "http://search.cpan.org/perldoc?CPAN::Meta::Spec",
"version" : "2"
},
"name" : "Linux-Inotify2",
"no_index" : {
"directory" : [
"t",
"inc"
]
},
"prereqs" : {
"build" : {
"requires" : {
"ExtUtils::MakeMaker" : "0"
}
},
"configure" : {
"requires" : {
"ExtUtils::MakeMaker" : "0"
}
},
"runtime" : {
"requires" : {
"common::sense" : "0"
}
}
},
"release_status" : "stable",
"version" : "2.3"
}